#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

sub My::Filters::known {}
sub My::Filters::forward;

for my $string (qw(My::Filters::known
                   My::Filters::unknown
                   My::Filters::forward)
) {
    say join "\t", $string, defined &$string, exists &$string;
}
[download]

Output:

My::Filters::known    1    1
My::Filters::unknown        
My::Filters::forward        1
[download]

I do not understand how your expression &$string works. The documentation for exists tells us that the expression must return the name of a subroutine. It appears to me that this would only be true for your expression if $string is a symbolic reference (which is prohibited by use strict). I would expect you need string interpolation (perhaps "&$string") but this syntax throws an error that the argument of exists is not a subroutine.
Bill

It seems the documentation uses the term "subroutine name" in quite a confusing way. Check the examples:

Use of a subroutine call, rather than a subroutine name, as an argument to exists is an error.

exists ⊂    # OK
exists &sub();  # Error
[download]

So, in this context, "subroutine name" includes the ampersand.

Considering strict, note the exceptions to strict 'refs':

$bar = \&{'foo'};
&$bar;
[download]

We are not calling the subroutine, we're just checking it exists/is defined.
map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

That's great. Thanks very much
--
Clayton

    sub My::Filters::known { }
    sub My::Filters::forward;
    for my $string (qw[known unknown forward]) {
        warn $string if My::Filters->can($string);
    }
[download]

    sub My::Filters::known { }
    sub My::Filters::forward;
    sub My::Other::Filters::forward;
    for my $package (qw[My::Filters My::Other::Filters]) {
        for my $func (qw[known unknown forward]) {
            warn $package . '::' . $func if $package->can($func);
        }
    }
[download]

Thanks for this answer, I'll try this out as well
--
Clayton