Re^3: Windows: AnyEvent -> HTTP -> DNS

So, looking at Net::DNS::Resolver::Base::nameservers(), I see one code path that tries to run a name lookup:

foreach my $ns ( grep {defined} @_ ) {
  if ( _ipv4($ns) || _ipv6($ns) ) {
    push @ip, $ns;
  } else {
    my $defres = ref($self)->new( debug => $self->{debug} );
    $defres->{persistent} = $self->{persistent};
    my $names  = {};
    my $packet = $defres->send( $ns, 'A' );
[download]

That would happen if the nameserver list passed to ->nameservers(@list) contained a string that wasn't an IP address. It seems really odd to me that name servers would ever be specified as names that needed resolved before they could be used to resolve names... maybe you should debug that first to see what the input is?

Try this: (example of monkey-patching)

  use Net::DNS::Resolver::Base;
  my $orig= \&Net::DNS::Resolver::Base::nameservers;
  local *Net::DNS::Resolver::Base::nameservers= sub {
    my ($self, @servers)= @_;
    print "Current nameservers value: "
      .join(", ", @{$self->{nameservers}//[]})
      ."\n";
    print "Assigning nameservers: ".join(", ", @servers)."\n"
      if @servers > 1;
    $orig->(@_);
  };

  # and then the rest of your program
[download]

I don't have a windows system to test on at the moment (well, not one where I can disable the network adapters and still use it) but that will at least show you what is getting assigned there. On my system, it reveals that the default resovlers are "127.0.0.1" and "::1" before the first call to ->nameservers, so yes that would hang if there was not a nameserver listening on localhost and something tried to assign "foo.example.com" as a nameserver.

Meanwhile, I realized that you can override the default timeouts like this:

  use Net::DNS::Resolver;
  Net::DNS::Resolver->tcp_timeout(1);
  Net::DNS::Resolver->udp_timeout(1);

  # remainder of your program
[download]

That effect comes from the AUTOLOAD method on ::Base which generates accessors on demand:

sub AUTOLOAD {                          ## Default method
  my ($self) = @_;

  my $name = $AUTOLOAD;
  $name =~ s/.*://;
  croak qq[unknown method "$name"] unless $public_attr{$name};

  no strict 'refs';          ## no critic ProhibitNoStrict
  *{$AUTOLOAD} = sub {
    my $self = shift;
    $self = $self->_defaults unless ref($self);
    $self->{$name} = shift || 0 if scalar @_;
    return $self->{$name};
  };

  goto &{$AUTOLOAD};
}
[download]

so any time you call an accessor on the package itself, it pulls up the _default resolver and sets the attribute on it instead. Those attributes get used as the defaults for any new resolvers created.

Comment on Re^3: Windows: AnyEvent -> HTTP -> DNS - > Blocking for minutes Select or Download Code

Replies are listed 'Best First'.
Re^4: Windows: AnyEvent -> HTTP -> DNS - > Blocking for minutes by hippo (Archbishop) on Oct 20, 2022 at 08:43 UTC
It seems really odd to me that name servers would ever be specified as names that needed resolved before they could be used to resolve names... This is used in the testing/using of authoritative and/or delegated nameservers which are usually specified by name rather than by address (so that they may be rotated, migrated, etc. by the hoster without affecting the delegation). So long as you have bootstrapped correctly by having an initial resolver to do the lookups of the nameserver names it is a handy feature. 🦛	[reply]
Re^4: Windows: AnyEvent -> HTTP -> DNS - > Blocking for minutes by sectokia (Friar) on Oct 20, 2022 at 04:26 UTC
Yes for me I get attempts to 127.0.0.1 and ::1 as well Setting tcp_timeout and udp_timeout changed nothing for me. Having a look in _udp_send the timeout used for can_read is made from the 'retrans' and 'retry' settings. Based on the default values (5 and 4) with the DNS timeout of 2.5s doubling, this results in a timeouts of: 2.5,2.5,5,5,10,10,20,20 for both servers (total 150 seconds). This reduced the issue to 2.5 seconds: `Net::DNS::Resolver->tcp_timeout(1); Net::DNS::Resolver->udp_timeout(1);` [download] But then I noticed that the local host name servers are in the defaults as well! So this 'fixes' it by setting the default nameservers to nothing: `Net::DNS::Resolver->nameserver4([]); Net::DNS::Resolver->nameserver6([]);` [download]	[reply] [d/l] [select]
Re^5: Windows: AnyEvent -> HTTP -> DNS - > Blocking for minutes by NERDVANA (Priest) on Oct 20, 2022 at 23:12 UTC
Well it sounds like you have enough info now that your problem is solved? If so, wonderful :-) ...but your post still leaves me with all kinds of questions, like why you need AnyEvent DNS to work if you don't have any network adapters in the first place, or how you're going to use a name server by host name if you don't have an initial default nameserver to resolve that with :-) I'll point back to my first post here about how if you know what name servers you want to use (like Cloudflare 1.1.1.1 or google 8.8.4.4) you can just pass those directly to AnyEvent::DNS and skip messing with Net::DNS::Resolver. Then if your network is connected, you can reach 1.1.1.1, and if it isn't, it should time out within AnyEvent rather than Net::DNS::Resolver.	[reply]
Re^6: Windows: AnyEvent -> HTTP -> DNS - > Blocking for minutes by sectokia (Friar) on Oct 21, 2022 at 01:13 UTC
The problem wasn't that I need to make HTTP requests when there is no DNS, its about behavior of my Perl programs when networks are disconnected. For instance: If the PC disconnects from all networks, then any time the code attempts to do a AnyEvent HTTP request - it would block for 150 seconds - a complete block with the event loop no longer running. In that event loop I could be running things like AnyEvent:HTTPD to handle requests from a localhost user GUI, or I could have scheduled timers that I expect to occur within that 150 seconds, also AnyEvent Signal handlers can't run. So essentially the entire program 'freezes' for 150s trying to do the syncronous call to a non existent DNS server on localhost. The correct 'fix' here is probably for AnyEvent::DNS to use AnyEvent::DNS::Resolver as per my solution - with the DNS default nameservers removed - to ensure the constructor can never go down a code path of making a DNS call via AnyEvent::DNS::Resolver.	[reply]