use Pod::Usage;

# is the same as

BEGIN {
   require Pod::Usage;
   Pod::Usage->import();
}
[download]

Assuming that often you run without ever using the Pod functions, and you want to fire that module up only if you will be needing it, you could have a runtime flag like this:

if ($needPod)
{
    require Pod::Usage;
    Pod::Usage->import();
}
[download]

Usually GetOPt::Std is enough for me. I almost never use autodie and absolutely never use it in end user code.

Ah. Then why not use Pod::Usage if $needPod;

> use Pod::Usage if $needPod;

Timing! You can't make a compile-time use (the BEGIN-part) depend on run-time conditions.

FWIW: you could use the if pragma, but only if the condition is available at compile-time

Because use takes effect at compile time, it doesn't respect the ordinary flow control of the code being compiled. In particular, putting a use inside the false branch of a conditional doesn't prevent it from being processed. If a module or pragma only needs to be loaded conditionally, this can be done using the if pragma:

use if $] < 5.008, "utf8";
use if WANT_WARNINGS, warnings => qw(all);
[download]

but as you see the conditions here are (compile time) constants

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

use Getopt::Long;
sub pod2usage { require Pod::Usage; goto \&Pod::Usage::pod2usage; }
GetOptions(
   ...
   ...
) or pod2usage(2);
[download]

On that note, someone ought to contribute a patch to Pod::Usage that avoids loading anything until it gets called. Then I could skip that bit of ugly boilerplate in my code.

The eval q{use Pod::Usage}; will work, though those who are allergic to stringy evals will probably prefer something more like

require Pod::Usage;
Pod::Usage::pod2usage( ... );