update

I don't recommend the following code anymore

rather

    if ( my (@caps) = ($line =~ $re) ) {
        no warnings 'uninitialized';
        @caps = () if $caps[0] ne $1;           # reset pseudo capture
+s
        $cb->(@caps);
        last;
    }
[download]

/update

This should be backward compatible

    my (@matches) = ($line =~ $re)
    if (defined $&) {
        $cb->(@matches);
        last;
    }
[download]

use v5.12;
use warnings;

for my $str ("AB","") {
    say "****** str=<$str>";
    for my $re ( qr/../, qr/(.)(.)/, q/XY/, q/(X)Y/, q// ) {
        say "--- re=<$re>";
        my @captures = $str =~ $re;
        if ( defined $& ) {
            say "matched"
        } else {
            say "no match"
        }
        if (defined $1) {
            say "with captures <@captures>";
        } else {
            say "no captures";
        }
    }
}
[download]

But...

> See "Performance issues" above for the serious performance implications of using this variable (even once) in your code.

perlvar

map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

OK, I thought this performance issue was resolved for versions newer than 10-15 years.

Anyway

${^MATCH}
This is similar to $& ($MATCH) except that it does not incur the perfo
+rmance penalty associated with that variable.

This variable was added in Perl v5.10.0.
[download]

though I don't understand the /p comment

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

>

    my (@matches) = ($line =~ $re)
    if (defined $&) {
        $cb->(@matches);
        last;
    }
[download]

nope, the real problem is that @matches = (1) if it matched without capture groups in $re

new attempt:

    
    if ( my (@caps) = ($line =~ $re) ) {
        @caps = () if $caps[0] ne $1;           # reset pseudo capture
+s
        $cb->(@caps);
        last;
    }
[download]

Full backwards compatible and no performance penalty.

OK?

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

if ( my (@caps) = ($line =~ $re) ) {
    @caps = () if $caps[0] ne $1;           # reset pseudo captures
    $cb->(@caps);
    last;
}
[download]

In
    @caps = () if $caps[0] ne $1;
$1 will be undefined if there is no capture group 1 or it is something like (...)? that fails to match (but an overall match can still occur). Warnings will be generated.

Although it's only compatible back to version 5.6, an alternative would be

c:\@Work\Perl\monks>perl

use strict;
use warnings;

use Data::Dump qw(pp);

my $cb = sub { print "matched,  captured ", pp @_; };

for my $str ("AB","") {

    for my $re (qr/../, qr/(.)(.)/, qr/(X)?(.)/, qr/XY/, qr/(X)Y/, qr/
+/) {

        print "str <$str>  re $re  ";

        if ( my (@caps) = ($str =~ $re) ) {
          # @caps = () if $caps[0] ne $1;  # reset pseudo capture
            $#caps = $#- - 1;  # reset pseudo capture
            $cb->(@caps);
            }
        else {
            print 'NO match';
            }

        print "\n";

        }

    }

^Z
str <AB>  re (?-xism:..)  matched,  captured ()
str <AB>  re (?-xism:(.)(.))  matched,  captured ("A", "B")
str <AB>  re (?-xism:(X)?(.))  matched,  captured (undef, "A")
str <AB>  re (?-xism:XY)  NO match
str <AB>  re (?-xism:(X)Y)  NO match
str <AB>  re (?-xism:)  matched,  captured ()
str <>  re (?-xism:..)  NO match
str <>  re (?-xism:(.)(.))  NO match
str <>  re (?-xism:(X)?(.))  NO match
str <>  re (?-xism:XY)  NO match
str <>  re (?-xism:(X)Y)  NO match
str <>  re (?-xism:)  matched,  captured ()
[download]

Update: But see haukex's reply about the preference for $#+ versus $#- (@+ versus @-) regex special variables.

---

Give a man a fish:  <%-{-{-{-<