Bod, I suggest you consider dropping your "major exception" in favour of LanX's excellent advice. That is, I prefer LanX's:

$input //= 1;  # default if undefined
[download]

$input = 1 unless defined $input;
[download]

See also:

• Set default values with the defined-or operator (Effective Perler)
• How to set default values in Perl (perlmaven)
• Perl Best Practices (reserve postfix if for flow-of-control)

> How to set default values in Perl

Gabor is mixing two cases in his article,

• defaulting undef values
• defaulting missing values (like with the hashes)
But doesn't give an example for missing values in arrays.

TIMTOWTDI, alas not very DRY

  DB<30> x @_
0  1
1  2
  DB<31> x ($a,$b,$c,$d) = (@_, ("D1".."D4")[@_..3])
0  1
1  2
2  'D3'
3  'D4'
  DB<32>
[download]

or

  DB<32> @DEF= ("D1".."D4")

  DB<33> x ($a,$b,$c,$d) = (@_, @DEF[@_..$#DEF])
0  1
1  2
2  'D3'
3  'D4'
  DB<34>
[download]

edit

or

use v5.12.0;
use warnings;
use Data::Dump qw/pp dd/;


sub test {
    my ($x, $y, $z) =
      ( @_,
        ("X","Y","Z")[@_..42]
      );

    pp ($x, $y, $z);
}

test(1..$_) for 0..3
[download]

-->

("X", "Y", "Z")
(1, "Y", "Z")
(1, 2, "Z")
(1, 2, 3)
[download]

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}

> $input = 1 unless $input;

Careful! Many things are false in Perl, like 0 or ""

You probably meant

$input = 1 unless defined $input;

Anyway, both are IMHO better written as

$input ||= 1;  # default if false
               # or 
$input //= 1;  # default if undefined
[download]

Careful! Many things are false in Perl, like 0 or ""

Oh yes - care is needed. But very often that's exactly what I want.

A common use case is query strings from HTML forms with checkboxes. The query string will have the key with no value. So if that's decoded into a Perl hash, the hash will be defined and the key exists but I want it to return false as it is an empty string.

When dealing with empty strings, I'd rather check length

Edit

  DB<13> p "false" unless "0"
false
  DB<14> p "false" unless 0
false
  DB<15> p "false" unless length "0"

  DB<16> p "false" unless length undef
false
  DB<17> use warnings; length undef

  DB<18> p "false" unless length ""
false
  DB<19>
[download]

Cheers Rolf
_{(addicted to the 𐍀𐌴𐍂𐌻 Programming Language :)
Wikisyntax for the Monastery}