It doesn't. It returns a single restaurant node. But you proceed to print it and all of its descendants.

To get the desired nodes, you can use the following:

my @nodes =
   $doc->findnodes( '/restaurant/*[ not( self::breakfast_menu ) ]' );
[download]

Maybe you'll find it more useful to simply delete the offending node.

$_->unbindNode() for $doc->findnodes( "/restaurant/breakfast_menu" );
[download]

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::LibXML;

my $dom = 'XML::LibXML'->load_xml(location => shift);
my $root = $dom->getDocumentElement();

my ($bfm) = $root->findnodes('//breakfast_menu');
say for $bfm->findnodes('(following-sibling::* | preceding-sibling::*)
+');
[download]

Or, keeping the xpath expression simple, plus testing element after breakfast menu:

#!/usr/bin/env perl

use strict;
use warnings;

use XML::LibXML;

my $dom = XML::LibXML->load_xml(string => <<'EOT');
<?xml version="1.0" encoding="UTF-8"?>
<restaurant>
   <timestart>0600</timestart>
   <timeend>1030</timeend>
   <city>Boston</city>
   <country>US</country>
   <breakfast_menu>
        <food>
                <name>Belgian Waffles</name>
                <price>$5.95</price>
                <description>Two of ...</description>
                <calories>650</calories>
        </food>
        <food>
                <name>Strawberry Belgian Waffles</name>
                <price>$7.95</price>
                <description>Light Belgian ...</description>
                <calories>900</calories>
        </food>
   </breakfast_menu>
   <edgecase>test after breakfast</edgecase>
</restaurant>
EOT

my $root = $dom->getDocumentElement();

for ($root->findnodes('/restaurant/*')) {
    next if 0 == index($_, '<breakfast_menu>');
    print "$_\n";
}
[download]

Output:

<timestart>0600</timestart>
<timeend>1030</timeend>
<city>Boston</city>
<country>US</country>
<edgecase>test after breakfast</edgecase>
[download]

Note: If you only want elements before breakfast menu, change next to last in the for loop.

You used

next if 0 == index( $_, '<breakfast_menu>' );
[download]

That would fail if it the serialization has any attributes or a prefix. Also, it completely ignores the namespace. The correct way to do the check outside of the XPath:

next
   if $_->nodeName eq "breakfast_menu"
   && !defined( $_->namespaceURI );
[download]