#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11152408
use warnings;
$SIG{__WARN__} = sub { die $@ };

# NOTE missing ; was added

my $diff = <<EOF; # NOTE $ not @
     @@ -3,7 +3,7 @@;
     id : 6109;
     name: abc;
     value: 0;
    - status: ?;
    + status: C;
      time: 2023-01-01 12:00;
      @@ -3,8 +3,8 @@;
     id : 6109;
     name: abc;
    - value: 0;
    - status: ?;
    + value: 2;
    + status: CS;
      time: 2023-01-01 12:03;
    @@ -3,7 +3,7 @@;
     id : 6109;
     name: abc;
     value: 0;
    - status: ?;
    + status: C;
      time: 2023-01-01 12:05;
EOF

my @ids;
for ( split /(?=^\s*@@)/m, $diff )
  {
# print "----------------------------------------\n$_\n\n";
  my ($id) = /^\s*id : (\d+)/m;
  my ($time) = /^\s*time: (.+);/m;
  my @fields;
  push @fields, "before $1 is $2 after is $3"
    while /^\s*- (\w+): (.+);\n(?=(?:.*\n)*\s*\+ \1: (.*);\n)/gm;
  local $" = ', ';
  push @ids, "$id changed on $time, @fields.\n";
  }

print sort { $a =~ s/ .*//sr <=> $b =~ s/ .*//sr } @ids;
[download]

Outputs:

6109 changed on 2023-01-01 12:00, before status is ? after is C.
6109 changed on 2023-01-01 12:03, before value is 0 after is 2, before
+ status is ? after is CS.
6109 changed on 2023-01-01 12:05, before status is ? after is C.
[download]