Hello noviceuser. Your code looks OK and will work, although there are a couple of things you might want to look at if interested.

open(MY_LOG, $log) or die "Could not open file 'log' $!";

Bareword filehandles like MY_LOG are apparently being phased out of the language. Instead you can use a lexical variable to hold the filehandle. eg:

open(my $lfh, $log) or die "Could not open file 'log' $!";
[download]

It's good that you have the conditional die statement, but it doesn't contain the filename which is another good piece of info to provide to the user on error, so I would include that too:

open(my $lfh, $log) or die "Could not open log file '$log': $!";
[download]

Presumably you are only opening the file for reading, so it's worth popping that in there as well:

open(my $lfh, '<', $log) or die "Could not open log file '$log': $!";
[download]

And finally, you don't need the brackets - they do no harm but you might find that the fewer punctuation characters there are on a line the easier it is to read.

open my $lfh, '<', $log or die "Could not open log file '$log': $!";
[download]

The other slightly odd thing is that you are chomping the lines read. Why is that? If the only action is to match against a pattern and conditionally print then it makes more sense not to chomp in this particular case.

These are all just "bonus" points but if you are just starting out with Perl now is a great time to try to reinforce good habits and best practices that will serve you well for a long time to come.

An even better way to report an error would be croak() from the Carp module. This provides a stack trace. While that doesn't matter in a very simple linear program, things change quite a bit as soon as you write a single function that could be called from multiple places.

#!/usr/bin/env perl

use v5.36;
use strict;
use warnings;

use Carp;

# --------- make demo file
open(my $ofh, '>', 'exists.dat') or croak($!);
for(1..3) {
    print $ofh "BLA\n";
}
close $ofh;
#---------

print "exists.dat has ", countLines('exists.dat'), " lines\n";

my $linecount = 0;
foreach my $fname (qw[exists.dat doesnotexist.dat]) {
    $linecount += countLines($fname);
}

sub countLines($fname) {
    my $linecount = 0;
    open(my $ifh, '<', $fname) or croak("$!");
    while((my $line = <$ifh>)) {
        $linecount++;
    }
    return $linecount;
}
[download]

When we run it, we get a nice backtrace:

$ perl carptest.pl 
exists.dat has 3 lines
No such file or directory at carptest.pl line 26.
    main::countLines("doesnotexist.dat") called at carptest.pl line 21
[download]

PerlMonks XP is useless? Not anymore: XPD - Do more with your PerlMonks XP

$. is the current line number that you can use in your printf?|say statement ...

printf( qq[%04d %s\n], $., $line );
[download]