Hello sundialsvc4,

Update: My conclusion was wrong, keys does consume more memory than each. See choroba’s comment and my reply, below.

Is Perl going to build an in-memory anonymous array of all those keys, in order to subsequently foreach through it?

No, Perl uses the same internal iterator in both cases:

So long as a given hash is unmodified you may rely on keys, values and each to repeatedly return the same order as each other.
...
Each hash or array has its own internal iterator, accessed by each, keys, and values.
— quoted from each, but see also keys and values.

Note that this internal iterator (one per hash) is implicitly reset when successive calls to each (or keys, or values) have exhausted the available hash entries. But it can also be reset explicitly, for which the recommended method is to call keys @array in void context (see values).

Hope that helps,

The iterator is used by keys, but not on each iteration of the for loop, but for the construction of the list of keys. Otherwise, the following program wouldn't output

$VAR1 = {
          'x' => 'cabd'
        };
[download]

The value would be shorter, as there would be less keys after the second iteration.

#!/usr/bin/perl
use warnings;
use strict;

use Data::Dumper;

my %hash = ( a => 11,
             b => 12,
             c => 13,
             d => 14,
           );

for my $key (keys %hash) {
    delete $hash{$_} for qw( a b c d );
    $hash{'x'} .= $key;
}
print Dumper \%hash;
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

Hello choroba,

Yes, you’re right: despite the calls to delete, the for loop list doesn’t change, so it must be constructed before the first loop iteration.

Whereas using each I get an infinite loop:

use warnings;
use strict;
use Data::Dump qw(dd pp);

my %hash =
(
    a => 11,
    b => 12,
    c => 13,
    d => 14,
);

while (my ($key, $value) = each %hash)
{
    print "key is $key, value is $value, hash is ", pp(\%hash), "\n";
    delete $hash{$_} for qw( a b c d );
    $hash{x} .= $key;
}

dd \%hash;
[download]

Output:

23:43 >perl 1148_SoPW.pl
key is c, value is 13, hash is { a => 11, b => 12, c => 13, d => 14 }
key is x, value is c, hash is { x => "c" }
key is x, value is cx, hash is { x => "cx" }
key is x, value is cxx, hash is { x => "cxx" }
key is x, value is cxxx, hash is { x => "cxxx" }
key is x, value is cxxxx, hash is { x => "cxxxx" }
key is x, value is cxxxxx, hash is { x => "cxxxxx" }
key is x, value is cxxxxxx, hash is { x => "cxxxxxx" }
key is x, value is cxxxxxxx, hash is { x => "cxxxxxxx" }
key is x, value is cxxxxxxxx, hash is { x => "cxxxxxxxx" }
...
[download]

Which isn’t surprising given the warning in the documentation for each:

If you add or delete a hash's elements while iterating over it, the effect on the iterator is unspecified; for example, entries may be skipped or duplicated--so don't do that. Exception: It is always safe to delete the item most recently returned by each()...

So it appears that sundialsvc4’s concern over memory is justified: for a large hash, the use of keys in a for loop will consume significantly more memory than the equivalent use of each. It seems strange to me that the documentation doesn’t highlight this — or did I just miss it somewhere?

Cheers,

Athanasius <°(((>< contra mundum

Iustus alius egestas vitae, eros Piratica,