use warnings;
use strict;

while (<DATA>) {
    s/(\w+)/ucfirst lc $1/e;
    print;
}

__DATA__
 BELLMONT NY
 NEW YORK NY
[download]

outputs:

 Bellmont NY
 New YORK NY
[download]

ucfirst upper cases the first letter and leaves the remaining letters unchanged so you need to lowercase the string first. That will give you the answer you claim to want, but not the result you indicate in your code. For that you need something more like:

use strict;
use warnings;

for my $str ('BELLMONT NY', 'NEW YORK NY') {
    my @words = split /\s+/, $str;
    
    $_ = ucfirst lc for grep {/\w{3,}/} @words;
    print "$str: ", join (' ', @words), "\n";
}
[download]

Prints:

BELLMONT NY: Bellmont NY
NEW YORK NY: New York NY
[download]

Another way:

c:\@Work\Perl>perl -wMstrict -le
"for my $s (' bElLmOnT NY', ' NeW yOrK NY', ' sAuLt StE. mArIe MI',) {
   my $t = $s;
   my $name = qr{ [[:alpha:]]+ [.]? }xms;
   $t =~ s{ \b ($name) (?= \s+ $name) }
          {\u\L$1}xmsg;
   print qq{'$s' -> '$t'};
   }
"
' bElLmOnT NY' -> ' Bellmont NY'
' NeW yOrK NY' -> ' New York NY'
' sAuLt StE. mArIe MI' -> ' Sault Ste. Marie MI'
[download]