This all comes back to the error message:

Type of arg 1 to keys must be hash or array (not list) at - line 3, ne
+ar "%Z)"
[download]

keys() really wants a hash as its single argument. Not a list. And %A, %Z is a list. Admittedly, it is a list of pairs that can again be interpreted as a hash, but keys() wants to have that hash.

Using +{ %A, %Z }->%* or %{{ %A, %Z }} constructs the list of pairs from the two hashes, wraps these in a hash reference and then dereferences that hash reference, giving the hash to keys(). This is why that one works.

Your other approaches fail because keys() only takes a single argument, and that argument must be a hash. Everything you try to pass to it is a list, because the comma operator "," creates a list or the assignments go through an intermediate list (and don't return the assigned hash).

If you are only interested in getting a unique list of keys, you could use List::Utils uniq, but that is not shorter than the two step approach, especially if you also later want to look at the combined values:

my @all_keys = uniq( keys(%A), keys(%Z) );
[download]

I didn't use uniq() because I need unique keys, not values, so I'd have to call keys() twice and then use uniq() on the results. I figured this was simpler, LOL. I guess I was just surprised---args are so flexible in Perl I figured that keys() would be able to operator on an overlaid pair. But I guess it's no different than push() requiring the first arg be an array (not a list, not an arrayref, but an actual array).

One expression, no lingering temp vars. But you're really trying to oversimplify.

my @all_keys = do { my %c = ( %A, %Z ); keys %c };
[download]

The keys function wants a single argument that's a just literal hash or array variable of some form (e.g. either a literal %foo or a postderef $bar->%*). It used to at one point be valid to give a scalar to keys and it would (I believe; not 100%) automagically deref. My guess when you tried to give it multiple items keys( %A, %Z ) it's parsing out as list context and you're actually passing it a list of the two hashes' contents unrolled which is why it's triggering the experimental scalar error and the error that you've given it more than one argument.

Edit: Also you might want to take into account the sizes of the hashes involved. It may be much less data copying to iterate over the keys of each candidate hash separately and create a hash from those then take keys of that instead so you're not copying all the values around as well. Which is what the aforementioned uniq is pretty much doing under the hood already (although that's going to build a temporary list of the all the keys to pass as args instead of just iterating over them).

And another thing: If you do make the big überhash be aware that the value is going to correspond to the last key seen from the last hash containing it which you use (e.g. %c = ( %A, %B ) if both have a key "a" the value in $c{a} will have what is in $B{a}).

I guess it's one expression but it has a block and a semicolon in it so... (lol)

I think you are right. When I tried to do keys(%A, %Z) it failed its arg magic and it was as if I had called keys("a", 1, "b", 2, "c", 3, "z", 9, "y", 8, "x", 7). It looked at its "one argument" ("a") and threw the "no scalars" error. I wouldn't call it a "bug" but it's a pretty misleading/confusing error message.

I'm not worried about the sizes. In general, an excellent piece of advice, but in this case there will be literally twos of keys in each hash. I just wanted the union quick and easy.

To your last point, sure, I use hash overlays on purpose all the time. In this case I only care about the keys, though.

  
%A = (a => 1, b => 2, c => 3);
%Z = (z => 9, y => 8, x => 7);

@all_keys = (keys %A , keys %Z);

print "@all_keys";

__END__
a b c x z y
[download]

This duplicates common keys.

Interestingly, with the postdereference, we can use a hash slice in an assigment:

my %A = (a => 1, b => 2, D => 3);
my %Z = (z => 9, y => 8, D => 7);
(\ my %all_keys)->@{keys %A, keys %Z} = ();
say for keys %all_keys;
[download]

The same construct using the "old" dereference doesn't work:

@{ \ my %all_keys }{keys %A, keys %Z} = ();
say for keys %all_keys;  # Global symbol "%all_keys" requires explicit
+ package name (did you forget to declare "my %all_keys"?)
[download]

because, alas, the my is scoped inside the dereference block.
map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]

(\ my %all_keys)->@{keys %A, keys %Z} = ();
[download]

What is the "\ my" doing? It seems to work without the "\".

Yeah sorry I missed that requirement.

The OP wasn't really a SSCCE tho. Duplicated keys would have shown the problem. :)

Personally I would go for a clear 2 line approach, all this dereferencing doesn't make it more readable.

Or to repeat my old mantra:

• Perl would be better of with autobox-methods¹ {%A, %Z}->keys
On a side note: I always have the feeling that a big deal of perl4's appeal got lost with my, because of conceptual problems.

Hmm...People will misunderstand this.

What I mean is that many things are elegantly solved if you don't need 'my'. A language design problem.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
see Wikisyntax for the Monastery}

¹) compare autobox

(\ my %all_keys)->@{keys %A, keys %Z} = ();

LOL, I cannot condone that foolery.