It is best explained using "deparse with extra parentheses":

% perl -MO=Deparse,-p -ce '($x) ? $z  = "true" : $z  = "false";'
(($x ? ($z = "true") : $z) = "false");
-e syntax OK
%
[download]

That's a lot of parens, the important pair is: ($x ? $z = "true" : $z) = "false".

The precedence is such that in this case, the ternary expression is $x ? $z  = "true" : $z. Let's call the result of that $y. That then forms the left hand side of $y = "false". So when $x is true it assigns "true" to $z, then yields $z as an lvalue to apply the second assignment $z = "false", immediately overwriting the "true".

The moral of the story is: put disambiguating parens round all but the simplest expressions in a ternary operator.

% perl -wle '$x = 1; $x ? ($z = "true") : ($z = "false"); print $z'
true
% # or of course make them simple expressions:
% perl -wle '$x = 1; $z = $x ? "true" : "false"; print $z'
true
%
[download]

Better use if-then-else construct instead, if you don't want to take advantage, but execute complex code.

 
my $z;
if ($x) {$z  = "true\n"} else {$z  = "false\n"}
[download]

But for my taste it's better written as

 
my $z = $x ? "true\n" : "false\n";
[download]

Your trap is even documented in perlop#Conditional-Operator

Because this operator produces an assignable result, using assignments without parentheses will get you in trouble. For example, this:

$x % 2 ? $x += 10 : $x += 2

Really means this:

(($x % 2) ? ($x += 10) : $x) += 2

Rather than this:

($x % 2) ? ($x += 10) : ($x += 2)

That should probably be written more simply as:

$x += ($x % 2) ? 10 : 2;

¹) See also WP : "The conditional operator's most common usage is to make a terse simple conditional assignment statement. "

²) tho I don't think I ever took advantage of the lvalue aspect, to create a LHS

  DB<22> 1 ? $a : $b = 1

  DB<23> x $a,$b
0  1
1  undef
  DB<24> 0 ? $a : $b = 2

  DB<25> x $a,$b
0  1
1  2
[download]

(I'd certainly use parentheses in productive code.)

B::Deparse is maybe illuminating. In either case it looks like the LHS of the second assignment winds up being $z which is then assigned "false\n".

$ perl -MO=Deparse,-p,-q -E '($x) ? $z  = "true\n" : $z  = "false\n"; 
+print $z;'
use feature 'current_sub', 'bitwise', 'evalbytes', 'fc', 'isa', 'modul
+e_true', 'postderef_qq', 'say', 'signatures', 'state', 'unicode_strin
+gs', 'unicode_eval';
(($x ? ($z = "true\n") : $z) = "false\n");
print($z);
-e syntax OK
[download]

So, short answer: use more brackets. I sprinkle a fair number of brackets in my code, and I'm also generous with white space. It helps clarify the meaning of the code, and hopefully avoids situations like this.

Longer answer: For your first example, I would write that as

  if ( $x ) { print "true\n"; } else { print "false\n"; }
[download]

  print "The truth value of x is " .
    ( $x ? 'true' : 'false' ) . "\n";
[download]

My suspicion is that the answer may lie in the precedence of operators. The = seems to be evaluated first, and then the the ?: group second. Am I right?

We could confirm this by doing : $z = 1; $x = 1; $z = $x ? $z = 2 : $z *= 9; print $z;

Now, the output is not 1, it's not 9 but 18. How does it become 18? The fact that it's 18 seems to suggest that first the $z = 2 gets evaluated, and then immediately after that the $z *= 9 gets evaluated. (Note: the = sign and *= are on the same level of precedence.)

Edit: Another interesting code is $z = 1; print $z *= 2, $z *= 9; # This prints 1818 instead of 218

Edit: I thought I was onto something, but apparently not. I'm just even more lost now. I did this :

my $A = 1;
my $B = 7; 
my $C = 5;
my $D = 0;

$D = $A ? $B *= 2 : $C *= 9;

print "A=$A B=$B C=$C D=$D";
[download]

And the output is..... :drum roll:

A=1 B=126 C=5 D=126

Okay. I give up. I'm lost! Maybe we discovered a bug? How does $B become 126? Lol

Am I right?

Yes, I think so.
The problem is fixed by changing the troublesome rendition to:

($x) ? ($z  = "true\n") : ($z  = "false\n"); print $z;
[download]

I sure am glad I generally go for the extra bit of typing and use if/else. Bloody hell ... the amount of time I can spend in a ternary op rabbit hole ... :-(
Thanks harangzsolt33, Fletch, hv.

Cheers,
Rob

say $x ? "true" : "false";
[download]

And it's called the conditional operator. It is merely a ternary operator, just like addition operator is a binary operator. It not even Perl's only ternary operator.

#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11161348
use warnings;

my $x = '1';
my $z = "undetermined\n";

($x) ? print "true\n" : print "false\n";
($x) ? $z  = "true\n" : $z  = "false\n"; print $z;

# fewer parens :)
$x ? $z  = "true\n" : ($z  = "false\n"); print $z;

# my preferred version
$z = $x ? "true\n" : "false\n"; print $z;
[download]