Assuming you're ok with loading the entire file into memory, you can use the following:

$str =~ s{$pat}{
   prompt( $_, $-[0], $+[0]-$-[0], $&, $repl, $`, $' )
   ? $repl
   : $&
}eg
[download]

use String::Substitution qw( interpolate_match_vars last_match_vars );

$str =~ s{$pat}{
   my $true_repl = interpolate_match_vars( $repl, last_match_vars() );
   prompt( $_, $-[0], $+[0]-$-[0], $&, $true_repl, $`, $' )
   ? $true_repl
   : $&
}eg
[download]

The latter supports interpolation of numerical captures such as $1 and ${1} in $repl, though you might need to escape some dollar signs and backslashes.

It's up to you to provide $str (the contents of the file), $pat (the pattern for which to search as a string or compiled regex), $repl (the replacement string) and prompt.

Args passed to prompt:

• $str
• The position in $str at which the match starts.
• The length of the match.
• The substring of $str that matched.
• The string with which the match will be replaced if prompt returns a true value.
• The substring of $str that precedes the match. Use however much of it that you want.
• The substring of $str that follows the match. Use however much of it that you want.

Have prompt return a true value to replace, or a false value to skip the replacement.

Update: Added second version and a lot of info.

Given that it's interactive, why not just use an editor? This task would be pretty trivial in an editor like vim.

..the following is not wise nor beuatiful, but it works (added some space for readability and please note windows double quotes!)

cat lorem.txt

Lorem ipsum dolor sit amet, consectetur adipisci elit,
sed do eiusmod tempor incidunt ut labore et dolore magna aliqua.
Lorem ipsum dolor sit amet, consectetur adipisci elit,
sed do eiusmod tempor incidunt ut labore et dolore magna aliqua.


perl -M"5;$S=shift;$R=shift;open $o,'>','new2.txt'" -ne "chomp;if($_=~
+/$S/){print qq/$_ $R?/;($_=$_)=~s/$S/$R/ if<STDIN>=~/y/}print$o $_.$/
+"  ipsum REPLACE lorem.txt

Lorem ipsum dolor sit amet, consectetur adipisci elit,  REPLACE?   y
Lorem ipsum dolor sit amet, consectetur adipisci elit,  REPLACE?   n

cat new2.txt

Lorem REPLACE dolor sit amet, consectetur adipisci elit,
sed do eiusmod tempor incidunt ut labore et dolore magna aliqua.
Lorem ipsum dolor sit amet, consectetur adipisci elit,
sed do eiusmod tempor incidunt ut labore et dolore magna aliqua.
[download]

L*

PS after some failure I gave up passing regexes as arguments and toying with perl -s ... -S=ipsum and whatalike

PPS add -MO=Deparse to see it better:

perl -MO=Deparse -M"5;$S=shift;$R=shift;open $o,'>','new2.txt'" -ne "c
+homp;if($_=~/$S/){print qq/$_ $R?/;($_=$_)=~s/$S/$R/ if<STDIN>=~/y/}p
+rint$o $_.$/"
sub BEGIN {
    require 5;
    ()
}
$S = shift @ARGV;
$R = shift @ARGV;
open $o, '>', 'new2.txt';
LINE: while (defined($_ = readline ARGV)) {
    chomp $_;
    if ($_ =~ /$S/) {
        print "$_ $R?";
        ($_ = $_) =~ s/$S/$R/ if readline(STDIN) =~ /y/;
    }
    print $o $_ . $/;
}
-e syntax OK
[download]

PPPS given perlrun doc inaccurate on -s switch

perl -M"5;open $o,'>','new2.txt'" -sne "chomp;if($_=~/$S/){print qq/$_ $R?/;($_=$_)=~s/$S/$R/ if<STDIN>=~/y/}print$o $_.$/"  -- -S=ipsum -R=REPLACE lorem.txt

..works!

You added some significant restrictions without mentioning them.

• Matches cannot span lines.
• Only one replacement will be attempted per line.

perlrun is silent about the need for "--" before arguments that start with "-", but it's not inaccurate about it.