If you're using Filter::Simple (or any other kind of source filter), that can easily throw __LINE__ off from what you see in your editor (example).

Another situation where the line numbers deviate from the source code is when you have multiline if statements, but here Perl reports (for example in warnings) the location of the if, not the location where the reason for a warning was encountered.

I'm not aware of other situations where __LINE__ differs from what you see in your text editor, but maybe with creative use of here-docs, you can provoke them.

# line 120
[download]

> $spinner->count('benchLoop', __FILE__, __LINE__);

can be reduced to $spinner->count('benchLoop') if you check caller to retrieve file and line inside the count() method.

Choroba's tip to use # line 123 directive is legit, see Plain-Old-Comments

So try to debug where the "strangeness" starts to happen in your file.

:~$ perl
$\="\n";   
print __LINE__;
# line 120
print __LINE__;
__END__
2
120
[download]

> Any idea why __LINE__ would be consistently off by 2?

Like Corion said, any module injecting code, like by using source filters could silently add additional lines.

Regarding your newline theory, try to end your file with __DATA__ and put this into your code right before calling ->count to check what the engine actually sees as different lines before compiling.

seek DATA,0,0;
my @lines = <DATA>;
say Dumper \@lines;
[download]

for instance

use v5.12; 
use warnings;
use Data::Dumper;
say __LINE__;
say __LINE__;
say __LINE__;


seek DATA,0,0;
my @lines = <DATA>;
say Dumper \@lines;

__DATA__
[download]

output

4
5
6
$VAR1 = [
          'use v5.12; 
',
          'use warnings;
',
          'use Data::Dumper;
',
          'say __LINE__;
',
          'say __LINE__;
',
          'say __LINE__;
',
          '
',
          '
',
          'seek DATA,0,0;
',
          'my @lines = <DATA>;
',
          'say Dumper \\@lines;
',
          '
',
          '__DATA__
'
        ];
[download]

The contents will be much more clear if you $Data::Dumper::Useqq=1; before the say Dumper

indeed, but I would use both options to be sure about differing interpretations of CR LF
<Reveal this spoiler or all in this thread>

Additionally one could run the file in the debugger and use the command 'v' or inspect @DB::dbline

Cheers Rolf
_{(addicted to the Perl Programming Language :)
see Wikisyntax for the Monastery}

here yet another approach to automatically introspect your source by using debugger flags - see $PERLDB:

(Crossposted at Reddit while PM was down)

BEGIN { $^P |= 0x400;};
use v5.12; 
use warnings;
use Data::Dump;

say "some code";

*DB::dbline = $::{ "_<" . __FILE__ };
ddx @DB::dbline;
[download]

OUTPUT:

perl /home/lanx/perl/pm/source_introspection.pl 
some code
# source_introspection.pl:9: (
#   undef,
#   undef,
#   "use v5.12; \n",
#   "use warnings;\n",
#   "use Data::Dump;\n",
#   "\n",
#   "say \"some code\";\n",
#   "\n",
#   "*DB::dbline = \$::{ \"_<\" . __FILE__ };\n",
#   "ddx \@DB::dbline;\n",
# )
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
see Wikisyntax for the Monastery}