A fluke.

You're using a key-value hash slice, which is used to obtain a list of key-value pairs from a hash.

$ perl -e'
   use v5.36;
   my %h = ( a => 1, b => 2, c => 3, d => 4 );
   say for %h{qw( a b )};
'
a
1
b
2
[download]

That's not possible in scalar context. In scalar context, it returns the value of the last key.

$ perl -e'
   use v5.36;
   my %h = ( a => 1, b => 2, c => 3, d => 4 );
   say scalar( %h{qw( a b )} );
'
2
[download]

In other words, it performs a simple hash lookup in scalar context. If you want to perform a hash lookup, it's much clearer to use a hash lookup instead of key-value hash slice.

$ perl -e'
   use v5.36;
   my %h = ( a => 1, b => 2, c => 3, d => 4 );
   say $h{ b };
'
2
[download]

In context, you used @{ %$hashref{ "To" } } aka @{ %{ $hashref }{ "To" } } aka @{ $hashref->%{ "To" } } aka $hashref->%{ "To" }->@* when it would have been clearer to use @{ $$hashref{ To } } aka @{ ${ $hashref }{ To } } aka @{ $hashref->{ To } } aka $hashref->{ To }->@*. There's already enough ways of doing this that it's easy to say it's wrong to add another level of complexity.

Update: s/hash slice/key-value hash slice/g, as per LanX's reply.

> You're using a hash slice,

Worse, it's the new extended kind which returns key-value pairs, forgot the terminology for it °

  DB<23> $hr= { To => [qw/a b c/] }

  DB<24> x %$hr{To}
0  'To'
1  ARRAY(0x55ef21ab6818)
   0  'a'
   1  'b'
   2  'c'
  DB<25> x @$hr{To}              # classic hash slice
0  ARRAY(0x55ef21ab6818)
   0  'a'
   1  'b'
   2  'c'
  DB<26> x @{%$hr{To}}           # only "works" with one hash key 
0  'a'
1  'b'
2  'c'
[download]

update

interestingly even the documentation of this module is faulty

https://metacpan.org/dist/Mail-IMAPClient/view/lib/Mail/IMAPClient.pod#parse_headers

    "To"      => [ "Big Shot <big.shot@bigco.com> ] ,

(spot the missing " )

I think the OP should use Data::Dumper or Data::Dump to inspect the $hashref and isolate his problem.

Cheers Rolf
_{(addicted to the Perl Programming Language :)
see Wikisyntax for the Monastery}

°) apparently key-value-slice since the "new" (cough) 5.20 ... wait... perldoc says Key/Value-Hash-Slice

Yes, sorry, that's what I meant and clearly demonstrated.