Had a lot of help from Mark Overmeer with this one ..

#!/usr/bin/perl

#
#   Name:  multipart-mo.pl
#
#   Extract names and email addresses from a maildir folder
# 
#   -  Also displays the number of messages (files) found and the numb
+er of parts in each message
#   -  Displays structure of each message and then outputs the names a
+nd email addresses
#   -  Where the name/email address is found in the 'body' part of a m
+essage (i.e NOT in From:, To:, Cc: etc,etc),
#             then usually only the email address will be returmed
#
#   This script has been adapted from multipart.pl , which is part of 
+the Mail::Box module , vers 2.118,
#   by Mark Overmeer   (http://http://search.cpan.org/dist/Mail-Box/ )
#
#   This code can be used and modified without restriction.
#
#   Usage:   perl multipart-mo.pl Smith\,\ Bill\ \&\ Nancy/     (maild
+ir folder name)
#

use warnings;
use strict;
use lib '..', '.';

use Mail::Box::Manager;

sub emails_from_body($);

#
# Get the command line arguments.
#

die "Usage: $0 folderfile\n"
    unless @ARGV==1;

my $foldername = shift @ARGV;

#
# Open the folder
#

my $mgr    = Mail::Box::Manager->new;

my $folder = $mgr->open($foldername, access => 'r')
    or die "Cannot open $foldername: $!\n";

#
# List all messages in this folder.
#

print "Mail folder $foldername contains ", $folder->nrMessages, " mess
+ages:\n";

my %emails;
 
foreach my $message ($folder->messages)
{   
    my @parts = ($message, $message->parts('RECURSE'));
    print $message->seqnr, ' has '.@parts." parts\n";
    $message->printStructure;

    foreach my $part (@parts)
    {
        foreach my $fieldname (qw/To Cc Bcc From Reply-To Sender/)
        {   my $field = $part->study($fieldname) or next;
            $emails{$_}++ for $field->addresses;
        }

        my $ct = $part->contentType || 'text/plain';
        $ct eq 'text/plain' || $ct eq 'text/html' or next;

        $emails{$_}++ for emails_from_body $part->body->decoded;
    }

}

print "$_\n" for sort keys %emails;
$folder->close;
exit 0;


### HELPERS

sub emails_from_body($)
{   
    $_[0] =~  /([-\w.]+@([a-z0-9][a-z-0-9]+\.)+[a-z]{2,})/gi;
}
[download]

It works. :)