/^((?:.*?(?: and| &) (*SKIP)(*FAIL))?)| (\Q$Jrnl\E)$/
[download]

Note that you can't capture the failed group, so $1 is empty.

UPDATE: See AnomalousMonk's reply below. My bad for misreading OP's problem. </UPDATE>

A clear explanation of where the word "text" originates in Lines 007 and 010 would be helpful.

But your chief problems are miscounting the captures and the failure of your regex to account for the space between "and" or &amp; and the journal name. Here's a less-overly-complicated version:

#!/usr/bin/perl
use 5.018;

my $RLine = "R.N. Raox, J. Pure and Appl. Phys.";

my $Jrnl  = qr/Appl. Phys./;

if( $RLine =~ /(.+)( and | & )($Jrnl)$/ ) { #NB trailing space bef
+ore the journal name
    print "11: $1\n";
    print "33: $3\n";
    print "Matched\n";
}
else {
    print "Not Matched\n";
}
[download]

 11: R.N. Raox, J. Pure
 33: Appl. Phys.
 Matched
[download]

Update: pasted wrong version of comment at Ln 008. Fixed.

Some thoughts:

• The regex you give matches against "R.N. Raox, J. Pure and Appl. Phys.", but I thought dominic01's OP wanted no match in this case because ' Appl. Phys.' is preceded by 'and';
• The regex defined by  my $Jrnl = qr/Appl. Phys./; will also match something like 'Applx Physy';
• You have the  use 5.018; statement at the beginning of your code, but nothing in the code seems to require version 5.18+.

---

Give a man a fish:  <%-(-(-(-<

The essence of the variable-width negative look-behind hack technique is that some part of a string that is needed in a subsequent match is matched and then "consumed" by  (*SKIP) (which prevents backtracking) when the match is then forced to fail. (The  \K operator already provides very nice variable-width positive look-behind.)

In the example below, the part that is "consumed" consists of some whitespace plus the entire  'Appl. Phys.' piece. If only a single whitespace character were guaranteed always to be present before  'Appl. Phys.' and this character was required for subsequent match, it would have been enough to consume only this character, but this seemed too fragile to me: more whitespace can easily creep in. Also, I have captured nothing because I don't understand just what you want from these captures: e.g., capturing the meta-quoted  'Appl. Phys.' is pointless because it's never going to change. What did you really want from these captures? (I'm also using non-capturing, atomic  (?>pattern) groups here rather than simple non-capturing  (?:pattern) groups because I think it makes reasoning about this trick a little easier.)

c:\@Work\Perl>perl -wMstrict -le
"use 5.010;
 ;;
 my $j = quotemeta 'Appl. Phys.';
 ;;
 LINE:
 for my $l (
   'R.N. Raox, J. Pure and Appl. Phys.',
   'R.N. Raox, J. Pure & Appl. Phys.',
   'R.N. Raox, J. Pure or Appl. Phys.',
   'R.N. Raox, J. Pure and or Appl. Phys.',
   'N.E. One, Fly Fishing and   Appl. Phys.',
   'N.E. One, Fly Fishing or   Appl. Phys.',
   ) {
   next LINE unless
     $l =~ m{ (?> (?> and | &) \s+ $j (*SKIP)(*F))? \s+ $j }xms;
   print qq{match: '$l'};
   }
"
match: 'R.N. Raox, J. Pure or Appl. Phys.'
match: 'R.N. Raox, J. Pure and or Appl. Phys.'
match: 'N.E. One, Fly Fishing or   Appl. Phys.'
[download]

Update: See the usual suspects: perlre (esp. Special Backtracking Control Verbs), perlretut, perlrequick.

First your solution works perfectly for me. Next your are right that the some of my "capturing" doesnt make any sense and I was just testing few things by capturing it.

Next I dont understand how to use the negative variable width look-back with (*SKIP)(*FAIL) when I have a huge regex. For e.g.

$Line =~ /^(Some_RegEx) (Some_RegEx) (Some_RegEx)(?<!foo.*|some text) 
+$Jrnl (Some_RegEx)$/;
[download]

Appreciate any pointers in this regard.

I don't have a good idea of your difficulties, but here's a generalized approach. I can't provide a working example at the moment, so the following is untested handwaving.

The  (*SKIP)(*FAIL) variable-width negative look-back hack works by messing up a match of something you need to have for an overall match. For a large regex, I tend to take the approach of factoring regex elements:

# stuff we want to capture
my $capture_this = qr{ ... }xms;
my $capture_too  = qr{ ... }xms;
my $capture_also = qr{ ... }xms;
my $capture_more = qr{ ... }xms;

# stuff we want to cause match failure if before certain other stuff
my $avoid_this = qr{ ... }xms;
my $avoid_too  = qr{ ... }xms;
my $avoid_also = qr{ ... }xms;
my $negatory   = qr{ (?> [aeiou]+ | f[eio]e? | $avoid_too) }xms;

# stuff we need for an overall match, may or may not be captured
my $needed_for_match = qr{ ... }xms;
my $needed_too       = qr{ ... }xms;

my $string = get_stringy_stuff();

my ($this, $too, $also, $yet_another) = $string =~ m{
    \A
    ($capture_this)
    ($capture_too)
    ...
    (?> (?> $avoid_this | $avoid_too | $avoid_also | etc) $needed_for_
+match (*SKIP)(*F))?
    $needed_for_match  # needed for overall match
    ($capture_also)
    ...
    (?> $negatory $needed_too (*SKIP)(*FAIL))?
    ($needed_too)  # needed for overall match, also captured
    \z                                 
    }xms;

do_something_with($this, $too, $also, $yet_another);
[download]

---

Give a man a fish:  <%-(-(-(-<