Hello programmercarlito,

Actually, the first two paragraphs are not working correctly as you believe. There are three problems. First, after $startAmount = <stdin> the variable $startAmount always ends in a newline character (or character sequence), so it is never the empty string. You need to chomp it before you test it.

Second, == compares numbers, but "" is a string. You should use eq instead: while($startAmount eq ""){.

Third, testing for an empty string won’t tell you whether the user has input a valid number. See How-do-I-determine-whether-a-scalar-is-a-number-whole-integer-float of perlfaq4.

Hope that helps,

Here's one way to structure things so that the coding is easier. (I'm just going with basic usage in this example - the module has various options and extra methods to make things easier for the person who is typing, such as keeping a history of responses, so they can be recalled and reused, etc. Notice that Term::ReadLine strips off the newline characters for you.)

#!/usr/bin/perl

use strict;
use warnings;
use Term::ReadLine;

my $term = Term::ReadLine->new();
my @prompts = ( "the starting amount",
                "your current age",
                "the age you want to retire",
                "amount deposited per year",
                "the annual interest rate",
                "expected retirement money" );
my %responses;

for my $prompt ( @prompts ) {
    my $response = '';
    until ( $response =~ /^\d+$/ ) {
        $response = $term->readline( "Enter $prompt: " );
        last unless defined( $response );
        if ( $response =~ /\D/ ) {
            warn "Numeric answers only, please.  Try again.\n";
        }
        elsif ( $prompt eq "the age you want to retire" and
                $response < $responses{"your current age"} ) {
            warn sprintf( "We can't change the past. Give me a number 
+> %d\n",
                          $responses{"your current age"} );
            $response = "";
        }
    }
    $responses{$prompt} = $response if ( defined( $response ));
}

printf "\nThank you for your %d answers\n", scalar keys( %responses );
for ( @prompts ) {
    print "  $_ : $responses{$_}\n" if ( exists( $responses{$_} ));
}
[download]

A module is definitely the way to go. I would prefer IO::Prompt::Hooked. It works on all operating systems and provides validation and retry.
Bill

You could also use IO::Prompter, which I only recently learned about.

#!/usr/bin/perl

use strict;
use warnings;
use feature qw/say/;

use IO::Prompter;

my %responses = ();
my @prompts = (
    ["startamount",     "the starting amount",          ""],
    ["startage",        "your current age",             ""],
    ["endage",          "the age you want to retire",   sub { $_ >= $r
+esponses{'startage'} } ],
    ["yearlydeposit",   "amount deposited per year",    ""],
    ["annualinterest",  "the Annual interest rate",     ""],
    ["expectedmoney",   "Expected Retirement Money",    ""],
);

foreach my $prompt (@prompts) {
    $responses{$prompt->[0]} = prompt "Enter $prompt->[1]:", -num => $
+prompt->[2]
}

foreach (sort keys %responses) {
    say "$_: $responses{$_}";
}
[download]

There's probably a better way of specifying empty constraints -- though the OP will likely some constraints that goes beyond "it's a number" imposed on most of the input.

++ for recommending my module (IO::Prompt::Hooked). I actually implemeneted a solution to the OP's question using IO::Prompt::Hooked last night, and it looked (in my opinion) great. ...but it became late, and I was too tired to submit a post around it. :)

Anyway, this is exactly the sort of thing that IO::Prompt::Hooked aims to simplify.




Dave

you might find How do I post a question effectively? interesting.

If you want only numbers, you have to check for numbers. One way to do that:

print"Enter the starting amount: ";
while( $startAmount !~ /^\d+/ ) {
    $startAmount = <STDIN>;
    chomp( $startAmount );
    if ( $startAmount !~ /^\d+$/ ) {
        print"Numbers only! Try again: ";
    } else {
        last;
    }
}
[download]

The above checks $startAmount twice. We can avoid that with a bare block and redo:

print"Enter the starting amount: ";
{
    chomp( $startAmount = <STDIN> );
    unless ( $startAmount =~ /^\d+$/ ) {
        print"Numbers only! Try again: ";
        redo;
    }
    # this line is reached if $startAmount is a number
    print "ok, \$startAmount is $startAmount\n";
}
[download]

There are many more ways to do that...

I don't recommend writing applications that interact with a user, asking the user to enter data. Such applications may seem beneficial to the end user, but not if that end user is another application. Rather, use tools that provide a means to accomplish both readability (for humans) and non-inter-activeness (for non-humans). In other words, consider using command line arguments over reading in "raw" STDIN.

#!/usr/bin/env perl

use strict;
use warnings;
use Data::Dumper;
use Getopt::Long;
use Pod::Usage;

my @opts = qw(
    starting-amount
    current-age
    retire-age
    deposit
    interest
    expected
);

GetOptions (
    ( \my %args => map "$_=i", @opts ),
    'help' => \my $help,
    'man'  => \my $man,
);
pod2usage( -verbose => 1 ) if $help;
pod2usage( -verbose => 2 ) if $man;

for (@opts) {
    pod2usage(
        -msg     => "$_ is required",
        -exitval => -1,
        -verbose => 0,
    ) unless defined $args{$_};
}

pod2usage(
    -msg     => "retire-age must be greater than current-age",
    -exitval => -1,
    -verbose => 0,
) if $args{'retire-age'} <= $args{'current-age'};


print Dumper \%args;

__END__
 
=head1 NAME

retirement-calculator - app to calculate retirement amount

=head1 SYNOPSIS

retirement-calculator [options]

 Options:
   --starting-amount   the amount to start retirement with
   --current-age       how old you currently are
   --retire-age        what age you want to retire at
   --deposit           amount deposited per year
   --interest          annual interest rate
   --expected          what you expect to retire with
   --help              list usage
   --man               print man page

=cut
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)