Re: This One's a Sieve

Nice! But the pedant in me feels compelled to point out that for a 35% increase in length, this obfu can be made significantly more time-efficient:

$m=250;print 2;for($b=3;$b<=$m;$b+=2){if(!$d[$a]){for($a=$b*$b;$a<=$m;
+$a+=$b){$c[$a]=1}}print",$b"}
[download]

The speed increase is negligible for low values of $m, but for large value it becomes significant (e.g. an increase of nearly 8 times in speed for $m equal to ten million):

use strict;
use warnings;
use Benchmark qw(:all) ;

my $m = 1e7;

cmpthese
(
    5,
    {
        Op  => sub { op();  },
        Ath => sub { ath(); },
    }
);

sub op
{
    my @c;
    my $last = 2;

    for (2 .. $m)
    {
        for (my $a = $_ * 2; $a <= $m; $a += $_)
        {
            $c[$a]++
        }

        $last = $_ if !$c[$_];
    }

    print "$last\n";
}

sub ath
{
    my @d;
    my $last = 2;

    for (my $a = 3; $a <= $m; $a += 2)
    {
        next if $d[$a];

        for (my $b = $a * $a; $b <= $m; $b += $a)
        {
            $d[$b]++
        }

        $last = $a;
    }

    print "$last\n";
}
[download]

Output:

23:05 >perl 1205_Obfu.pl
9999991
9999991
9999991
9999991
9999991
9999991
9999991
9999991
9999991
9999991
    s/iter   Op  Ath
Op    62.2   -- -87%
Ath   8.02 676%   --

23:11 >
[download]

But note that this version is still inefficient. See johngg’s recent post: Re^3: Number functions I have lying around, which saves on (1) cpu time by iterating only up to sqrt($m), and (2) memory by storing the sieve in a bit vector.

Hope this is of interest,

Athanasius <°(((>< contra mundum Iustus alius egestas vitae, eros Piratica,

Comment on Re: This One's a Sieve Select or Download Code

Replies are listed 'Best First'.
Re^2: This One's a Sieve by danaj (Friar) on May 07, 2015 at 16:13 UTC
Or better yet, one of the sieves shown on RosettaCode, which are 2.5 to 8 times faster than the johngg sieve.	[reply]
Re^3: This One's a Sieve by Anonymous Monk on May 07, 2015 at 19:03 UTC
Still better, the version that's idiomatic, clean, and more performant than anything on RosettaCode at the present time.	[reply]