Maybe one way:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @GI = (
   'gi|Q384722390|emb|WP_938420210.1|Gene name',
   'gi|342546780|emb|WP_934203412.1|Gene name',
   'gi|342546780|emb|WP_93420341211|Gene name',
   'gi|987654321|emb|WP_555555555.1|Jean name',
   );
 ;;
 my @Accession = qw(WP_938420210.1  WP_934203412.1);
 my ($rx_acc) =
   map qr{ $_ }xms,
   join q{|},
   map quotemeta,
   @Accession
   ;
 ;;
 GENE:
 for my $gi (@GI) {
   next GENE unless my ($acc) = $gi =~ m{ \b ($rx_acc) \b }xms;
   print qq{'$acc' in '$gi'};
   }
"
'WP_938420210.1' in 'gi|Q384722390|emb|WP_938420210.1|Gene name'
'WP_934203412.1' in 'gi|342546780|emb|WP_934203412.1|Gene name'
[download]

Updates:

1. Noticed accession numbers have  . (dot) metacharacter in them: added  map quotemeta, step to building accession number regex to make dot an ordinary literal character.
2. Added some negative matches to  @GI test cases.
3. The match expression  m{ (?<= [|]) ($rx_acc) (?= [|]) }xms may be preferable | is almost certainly better because  | (pipe) characters are exactly what must match before and after an accession number (\b just requires a word boundary). (Tested; same output.)
4. Usually, the regex engine begins searching a string from the beginning of the string. If you know that a match cannot possibly start before a certain character offset in the string, this information can be used to allow the RE to jump ahead in its search, skipping over characters in which there can be no match and potentially speeding a match. Further, if it is known that interpolated regex components (like  $n and  $rx_acc below) will not change during script execution, the  /o regex modifier (see  m/PATTERN/ in the Regexp Quote-Like Operators section of perlop) can be used to prevent regex re-compilation on each pass through the loop, again potentially speeding matches. So a loop like:

   my $n = 12;
   GENE:
   for my $gi (@GI) {
     next GENE unless
       my ($acc) = $gi =~ m{ \A .{$n,}? (?<= [|]) ($rx_acc) (?= [|]) }xms
   +o;
     print qq{'$acc' in '$gi'};
     }
   [download]

   (tested; same output) may be significantly faster; this can only be determined for certain by some kind of Benchmark-ing.
5. Actually, in answer to the question posed by hippo in the reply below, I think a hash-based approach would probably be more appropriate (insofar as I understand the problem): simpler, more maintainable, likely much faster than a regex approach.

Would a hash not be more appropriate? If we remove the \Q and \E from the data, then it's almost trivial:

#!/usr/bin/perl -w
use strict;
use warnings;

my @GI = ("gi|Q384722390|emb|WP_938420210.1|Gene name",
    "gi|342546780|emb|WP_934203412.1|Gene name");
my @Accession = ("WP_938420210.1","WP_934203412.1");

# Convert to hash
my %foo = ();
for my $gene (@GI) {
    my @fields = split (/\|/, $gene);
    $foo{$fields[3]} = $gene;
}

# Now extract
for my $accno (@Accession) {
    print "Acc no: $accno, Gene: $foo{$accno}\n";
}
[download]

If you wish to loop through an array, you probably want a for loop, not a while loop.

for my $target (@Accession) {

}
[download]

While inside the for loop, you can then grep out any rows that match from @GI:

    my @found = grep /$match/, @GI;
[download]

More than likely you only ever match one element, but you should be thinking about the notion that you might find multiples. Once you find your match(es), you will then most likely want to split the record(s) up. Put the whole thing together and you have something like this:

use strict;
use warnings;
use Data::Dumper;

my @GI = (
    'gi|Q384722390|emb|WP_938420210.1|Gene name',
    'gi|342546780|emb|WP_934203412.1|Gene name',
);
my @Accession = ( 'WP_938420210.1', 'WP_934203412.1' );

for my $match (@Accession) {
    my @found = grep /$match/, @GI;
    print "$match\n", Dumper [ split /\|/, $_ ] for @found;
}
[download]

UPDATE: You know ... since you already have all that data within @GI and it is already in memory, you could ease the problem by using a HoA (hash of arrays) instead of an Array that essentially contains unparsed CSV lines. Once you have this HoA, you simply lookup your accession value. The following code should demonstrate and notice that i am taking the liberty to rename these variables:

use strict;
use warnings;
use Data::Dumper;

my @genes = (
    'gi|Q384722390|emb|WP_938420210.1|Gene name',
    'gi|342546780|emb|WP_934203412.1|Gene name',
);

my @accession = ( 'WP_938420210.1', 'WP_934203412.1' );

my %genes = map {
    my @s = split /\|/, $_;
    ( $s[3] => [@s] );
} @genes;

print Dumper \%genes;

# list the 2nd field from each gene
for (@accession) {
    print $genes{$_}[1], $/;
}
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

for my $Accession (@Accession) {
    for my $GI (@GI) {
        if ($Accession =~ $GI) {
            print "$GI\n";
            last;
        }
    }
}
[download]

Please see my reply to james28909 questioning the wisdom of depending on certain characters (separators) of the data to be regex metacharacters while ignoring the fact that others are also.

---

Give a man a fish:  <%-(-(-(-<

use strict;
use warnings;

my @GI = (  "gi|Q384722390|emb|WP_938420210.1|Gene name",
            "gi|342546780|emb|WP_934203412.1|Gene name"
        );
my @Accession = qw( WP_938420210.1
                    WP_934203412.1
                    );

my $i = 0;

for my $A(@Accession) {
    for my $G(@GI) {
        if ( $A =~ $G ) {
            print "$G\n";
        }
    }
}
[download]

This approach depends on the fact that the CSV separator character in  "gi|Q384722390|emb|WP_938420210.1|Gene name" ( |(pipe)) is also the regex ordered alternation operator, but ignores the fact that  . (dot) in  |WP_938420210.1| is also a regex metacharacter that matches (almost) anything. Is this a good idea?

---

Give a man a fish:  <%-(-(-(-<