If you want to count overlapping matches, a plain regular expression as you wrote it isn't the easiest way to approach the problem.

Personally, I would simply iterate over the string either for each character or by resetting pos and using \G as documented in perlre:

use strict;
my $line= 'AAALVDENEC';
while( $line =~ /\G.*?(AA|AL|DA|DE|DV|VD|DW|QD|SD|HD|ED|DY|VE|EN|EI|KE
+|NV|VP|FV|SS|WK|KK)/igc ) {
    print sprintf 'Matched [%s] at %d', $1, pos($line);
    pos( $line )--;
}
[download]

Here's one way to match overlapping patterns:

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1124725

use Data::Dump qw(pp);
use strict;
$| = 1;
my %answer;

for my $line ( 'AAALVDENEC', 'AATLVDEGDG' )
  {
  $answer{$line}{$_}++ for $line =~
    /(?=(AA|AL|DA|DE|DV|VD|DW|QD|SD|HD|ED|DY|VE|EN|EI|KE|NV|VP|FV|SS|W
+K|KK))/g;
  }

pp \%answer;
[download]

which produces:

{
  AAALVDENEC => { AA => 2, AL => 1, DE => 1, EN => 1, VD => 1 },
  AATLVDEGDG => { AA => 1, DE => 1, VD => 1 },
}
[download]

That has the 5 and 3 you are looking for.

Thank you it worked.......thanks for the help

There is an alternative to matching with overlapping patterns:

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1124725

use strict;

my @dipeptides = split /\|/,
  'AA|AL|DA|DE|DV|VD|DW|QD|SD|HD|ED|DY|VE|EN|EI|KE|NV|VP|FV|SS|WK|KK';

for my $line ( 'AAALVDENEC', 'AATLVDEGDG' )
  {
  my $sum = grep $line =~ $_, @dipeptides;
  my $abs = @dipeptides - $sum;
  print "$line sum: $sum  abs: $abs\n";
  }
[download]