Re: Regex with variables

All the above are good; just a note for safety's sake, if your use of such a variable as the regular expression ever falls into risk of including metacharacters, you may need to use quotemetato convert it to a regular expression:

#!/usr/bin/perl
use strict;

my @inputData =
(
    'test.dat',
    'test.exe',
    'testadat.exe',
    'testaexe.dat',
);

my @regExp =
(
    'test.dat',
    'test.exe',
);

print "----- Without quotemeta ---------------\n";
foreach my $regularExpression (@regExp)
{
    print "Using regular expression /$regularExpression/:\n";
    foreach my $inputLine (@inputData)
    {
        if ($inputLine =~ /$regularExpression/)
        {
            print "    Match:  \"$inputLine\"\n";
        }
    }
}
print "----- With quotemeta ------------------\n";
foreach my $regularExpression (@regExp)
{
    my $actualRegularExpression = quotemeta $regularExpression;
    print "Using regular expression /$actualRegularExpression/:\n";
    foreach my $inputLine (@inputData)
    {
        if ($inputLine =~ /$actualRegularExpression/)
        {
            print "    Match:  \"$inputLine\"\n";
        }
    }
}
print "----- Fini ----------------------------\n";
[download]

Results:

D:\PerlMonks>regex1.pl
----- Without quotemeta ---------------
Using regular expression /test.dat/:
    Match:  "test.dat"
    Match:  "testadat.exe"
Using regular expression /test.exe/:
    Match:  "test.exe"
    Match:  "testaexe.dat"
----- With quotemeta ------------------
Using regular expression /test\.dat/:
    Match:  "test.dat"
Using regular expression /test\.exe/:
    Match:  "test.exe"
----- Fini ----------------------------

D:\PerlMonks>
[download]

Comment on Re: Regex with variables Select or Download Code

Replies are listed 'Best First'.
Re^2: Regex with variables by AnomalousMonk (Archbishop) on Jun 30, 2015 at 01:44 UTC
... use `quotemeta` ... ... or `\Q$string\E` its interpolative equivalent: c:\@Work\Perl\monks>perl -wMstrict -le "my @inputData = qw(test.dat test.exe testadat.exe testaexe.dat); ;; my @search_strings = qw(test.dat test.exe); ;; print '----- With quotemeta ------------------'; foreach my $search (@search_strings) { print qq{Using search string '\Q$search\E':}; foreach my $inputLine (@inputData) { if ($inputLine =~ m{ \Q$search\E }xms) { print qq{ Matched: '$inputLine'}; } } } " ----- With quotemeta ------------------ Using search string 'test\.dat': Matched: 'test.dat' Using search string 'test\.exe': Matched: 'test.exe' [download] Give a man a fish: `<%-(-(-(-<`	[reply] [d/l] [select]

Replies are listed 'Best First'.

Re^2: Regex with variables
by AnomalousMonk (Archbishop) on Jun 30, 2015 at 01:44 UTC

... use quotemeta ...

... or \Q$string\E its interpolative equivalent:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @inputData = qw(test.dat  test.exe  testadat.exe  testaexe.dat);
 ;;
 my @search_strings = qw(test.dat  test.exe);
 ;;
 print '----- With quotemeta ------------------';
 foreach my $search (@search_strings) {
   print qq{Using search string '\Q$search\E':};
   foreach my $inputLine (@inputData) {
     if ($inputLine =~ m{ \Q$search\E }xms) {
       print qq{  Matched: '$inputLine'};
       }
     }
   }
"
----- With quotemeta ------------------
Using search string 'test\.dat':
  Matched: 'test.dat'
Using search string 'test\.exe':
  Matched: 'test.exe'
[download]

Give a man a fish: <%-(-(-(-<

[reply]
[d/l]
[select]