1. Please use <code> tags. Without them your code is very hard to read. Fixed now.
2. To what box do you refer?
3. I can only guess that this is a scoping problem. Try declaring your variable first.

my $location_id;
if ($resp->is_success) { $location_id = $resp->header( 'Location' ); }
print $location_id;
[download]

Update: Now that the code is legible it is easy to see that you have declared $location_id twice in the same block. If you had used warnings this would have been alerted to you. Don't double-declare.

Please check now

As Hippo said:

Your question was how to use $location_id outside the box (the scope in which it was declared; your sub, or if statement...)

But you have a separate problem which is that you declare my $location_id twice. As Hippo said, you should always use warnings; at the top of your script, and perl will tell you about these errors. You must only declare a variable once.

When you have declared it with my $location_id, it will stay in existence until the end of your scope. If you have a "box" after you declare the variable, the variable will be available in the "box," and again once you exit the "box," reflecting any changes you made to its value inside the "box."

use strict;
use warnings;

my $location_id = 'foo';

if ($resp->is_success) { # the box?
  $location_id = 'bar';
}

say $location_id; # prints 'bar'
[download]

1. Your question is all about scoping.
2. hippo gave you a link for learning about scoping.
3. Not using use strict;is interfering with your ability to see the problem.
4. Not using use warnings;is also interfering with your ability to see the problem.
5. You define a variable's scope using the mystatement^*.
6. The scope of a variable (where you can use it) is determined by where you define it
7. If you want to use the variable outside of its current scope, move it

^*There are other ways to define a variable, but let's keep it simple for now and just work with the mystatement.

Perhaps some code snippets will help you visualize this:

This one will fail, but will fail silently since there is no use strict;:

my $test1 = 1;
{
    my $test2 = 2;
    print " Inside:  test1 = [$test1]  test2 = [$test2]\n";
}
print "Outside:  test1 = [$test1]  test2 = [$test2]\n";
[download]

Results:

D:\PerlMonks>scope1-fail.pl Inside: test1 = [1] test2 = [2] Outside: test1 = [1] test2 = [] D:\PerlMonks> [download]

<--- $test2 is blank! [download]

Adding use strict; allows us to see the problem:

use strict;

my $test1 = 1;
{
    my $test2 = 2;
    print " Inside:  test1 = [$test1]  test2 = [$test2]\n";
}
print "Outside:  test1 = [$test1]  test2 = [$test2]\n";
[download]

Results:

D:\PerlMonks>scope2-fail.pl
Global symbol "$test2" requires explicit package name at D:\PerlMonks\
+scope2-fail.pl line 8.
Execution of D:\PerlMonks\scope2-fail.pl aborted due to compilation er
+rors.

D:\PerlMonks>
[download]

Adding my $test2;outside the block clears the error, but it still fails silently:

use strict;

my $test1 = 1;
my $test2;
{
    my $test2 = 2;
    print " Inside:  test1 = [$test1]  test2 = [$test2]\n";
}
print "Outside:  test1 = [$test1]  test2 = [$test2]\n";
[download]

Results:

D:\PerlMonks>scope3-fail.pl Inside: test1 = [1] test2 = [2] Outside: test1 = [1] test2 = [] D:\PerlMonks> [download]

<--- $test2 is still blank! [download]

Adding use warnings;allows us to see what is wrong:

use strict;
use warnings;

my $test1 = 1;
my $test2;
{
    my $test2 = 2;
    print " Inside:  test1 = [$test1]  test2 = [$test2]\n";
}
print "Outside:  test1 = [$test1]  test2 = [$test2]\n";
[download]

Results:

D:\PerlMonks>scope4-fail.pl
 Inside:  test1 = [1]  test2 = [2]
Use of uninitialized value $test2 in concatenation (.) or string at D:
+\PerlMonks\scope4-fail.pl
line 10.
Outside:  test1 = [1]  test2 = []

D:\PerlMonks>
[download]

Finally, eliminating the duplicate mystatement (and adding other best practices like exit;and __END__ ), it runs and works:

use strict;
use warnings;

my $test1 = 1;
my $test2;
{
    $test2 = 2;
    print " Inside:  test1 = [$test1]  test2 = [$test2]\n";
}
print "Outside:  test1 = [$test1]  test2 = [$test2]\n";

exit;
__END__
[download]

Results:

D:\PerlMonks>scope5-win.pl
 Inside:  test1 = [1]  test2 = [2]
Outside:  test1 = [1]  test2 = [2]

D:\PerlMonks>
[download]

A lot of people make the mistake of leaving off strictand warningson the misguided belief that it makes their work easier. The truth is quite the opposite, as you can see. Let the Perl interpretter debug your code for you. Why do it the hard way?

In addition to the link given by hippo, take a look at some of the Tutorials in our very own Variables and Scoping section.