in reply to table from repeated strings text

wild guess - is this the kind of thing you are looking for ? 

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1134550

use warnings;
use strict;

my (@left, %left, @top, %top, %values);
my $all = '';

while(<DATA>)
   {
   $all |= $_ for my ($left, $top, $value) = split;
   $left{$left}++ or push @left, $left;
   $top{$top}++ or push @top, $top;
   $values{$left}{$top} = $value;
   }

my $len = length $all;
my $fmt = join(' ', map "%${len}s", 0..@top) . "\n";

printf $fmt, '', @top;
for my $left (@left)
   {
   printf $fmt, $left, map $values{$left}{$_} // '', @top;
   }

__DATA__
aaa bbb 123
aaa ccc 234
aaa ddd 345
bbb ccc 456
bbb ddd 567
ccc ddd 678

[download]

prints 

    bbb ccc ddd
aaa 123 234 345
bbb     456 567
ccc         678

[download]

Replies are listed 'Best First'.
Re^2: table from repeated strings text
by Anonymous Monk on Jul 13, 2015 at 19:19 UTC

    OK, I forgot the -'s 

    #!/usr/bin/perl

# http://perlmonks.org/?node_id=1134550

use warnings;
use strict;

my (@left, %left, @top, %top, %values);
my $all = '';

while(<DATA>)
   {
   $all |= $_ for my ($left, $top, $value) = split;
   $left{$left}++ or push @left, $left;
   $top{$left}++ or push @top, $left;
   $top{$top}++ or push @top, $top;
   $values{$left}{$top} = $value;
   }

my $len = length $all;
my $fmt = join('  ', map "%${len}s", 0..@top) . "\n";

printf $fmt, '', @top;
for my $left (@left)
   {
   printf $fmt, $left, map $left eq $_ ? '-' : $values{$left}{$_} // '
+', @top;
   }
__DATA__
aaa bbb 123
aaa ccc 234
aaa ddd 345
bbb ccc 456
bbb ddd 567
ccc ddd 678

    [download]

    prints

         aaa  bbb  ccc  ddd
aaa    -  123  234  345
bbb         -  456  567
ccc              -  678

    [download]
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom