vr has asked for the wisdom of the Perl Monks concerning the following question:

I thought that since 

'aa' =~ /(.)\1/

[download]

there can be something like:

use 5.010;
my @a = qw/a d/;
$_ = '0a1d1y0z';
say s/(\d)${a[\1]}/xx/g;
say;

[download]

And it'll say "2" and "xxxx1y0z", but of course it won't work.

I could capture each pair, and then decide on what to replace it with, in substitution part, with an "e" modifier. But I would like an "s" operator to return number of 'real' substitutions made.

I came up with 

say s/(\d)([a-z])(?(?{ $2 ne $a[$1] })(*FAIL))/xx/g;
say;

[download]

But it doesn't look very efficient nor pretty. Is there a better solution?

(In practice, there's not an array, but HoA, with keys being sub-matches and indices depending on external conditions. And matches are not simple pairs of characters, and strings are a little longer.)

Replies are listed 'Best First'.
Re: Using sub-matches to interpolate hash keys (array indices)?
by Anonymous Monk on Jul 21, 2015 at 13:10 UTC

    I realize this doesn't answer the question directly, but would building the regex dynamically be an option?

    my @a = qw/a d/;
my $re = join '|',
    map { $_.quotemeta($a[$_]) } 0..$#a;
print $re, "\n";
$_ = '0a1d1y0z';
print s/($re)/xx/g, "\n";
print $_, "\n";
__END__
0a|1d
2
xxxx1y0z

    [download]
[reply]
[d/l]

      Thanks a lot, I wouldn't have thought myself to check the variant that you suggested. There are about 30 (plus or minus) key-value pairs in my HoA, and, 'external conditions' being constant during a single replacement, it can be 'flattened' to a hash -- it means your pattern will have 30 alterations. Will it be more efficient than my regexp i.e. with code injection? Here's the test:

      use strict;
use warnings;
use 5.020;
use String::Random 'random_string';
use Benchmark 'cmpthese';

my $s = random_string( 'b' x 10000 );

my %h = map { chr, chr( $_ + 30 + rand 10) } 0 .. 29;
my $re = join '|', 
    map { quotemeta( $_.$h{$_} ) } keys %h;
    
my ( $s1, $s2 );

cmpthese( -5, {
    1 => sub { $_ = $s; s/([\x00-\x1D])(.)(?(?{ $2 ne $h{$1} })(*FAIL)
+)/xx/sg; $s1 = $_ },
    2 => sub { $_ = $s; s/$re/xx/sg; $s2 = $_ },
} );

say 'OK' if $s1 eq $s2;

__END__

     Rate    1    2
1  1028/s   -- -91%
2 11069/s 977%   --
OK

      [download]

      It's absolutely wonderful there are sites like this one.

[reply]
[d/l]

Back to Seekers of Perl Wisdom