Nice of you to use strictures, but pretty dumb to ignore the warnings they generate! Your "additional" test is doomed because it doesn't test the input line and the regular expressions are broken. The remaining code is doomed because you need to process each record as a unit, which is not what the code does. Instead consider:

use strict;
use warnings;

local $/ = 'END:VCARD';

while (my $record = <DATA>) {
    my ($name, $number) =
        $record =~ /FN:([^\n;]+).*\nTEL;[^\n]*PREF:([^\n;]+)/s;

    next if !defined $number;
    printf "%15s -> %s\n", $name, $number;
}

__DATA__
BEGIN:VCARD
VERSION:3.0
N:;Naresh;;;
FN:Naresh
TEL;TYPE=CELL;TYPE=PREF:+917734807608
END:VCARD
[download]

Prints:

         Naresh -> +917734807608
[download]

This code is not robust, but may help as a starting point for you.

I see that pme already showed you working code for parsing the file yourself. Alternatively, you could use the vCard module to access the data in your vcf files. For example,

BEGIN:VCARD
VERSION:3.0
N:;Naresh;;;
FN:Naresh
TEL;TYPE=CELL;TYPE=PREF:+917734807608
END:VCARD
[download]

#!/usr/bin/env perl

use strict;
use warnings;

use vCard;

my $vcard = vCard->new;

$vcard->load_file('file.vcf');

print "Full Name: ", $vcard->full_name, "\n";

my $pref_phone_num;

foreach my $phone ( @{$vcard->phones} ){
   if($phone->{preferred} == 1){
       $pref_phone_num = $phone->{number};
   }
}

print "Preferred Phone Number: ", $pref_phone_num, "\n";

exit;
[download]

Name: Naresh
Preferred Phone Number: +917734807608
[download]

I hope the comments help you to understand the code.

#!/usr/bin/perl

use strict;
use warnings;

my $filename = $ARGV[0];
my ($name, $number);

open my $fh, "<", "$filename" or die "$!";
open my $fh2, ">", "list.txt" or die "$!";

while (<$fh>) {                             # read line to variable $_
  chomp;                                    # removes any trailing str
+ing from $_
  if ( /^FN:(.*)/ ) {                       # get the name
    $name = $1;
  } elsif ( /=PREF:(.*)/ ) {                # get the number
    $number = $1;
    printf $fh2 "%15s -> %s\n", $name, $number; #  %d changed to %s in
+ order to keep leading '+'
  }

}

close $fh2 or die "$!";
close $fh or die "$!";
[download]

Hey i made it yeap..:)

use strict;
use warnings;

my $filename = $ARGV[0];
my ($name, $number);

open my $fh, "<", "$filename" or die "$!";
open my $fh2, ">", "list.txt" or die "$!";
while(my $line = <$fh>) {
    if( $line =~ /^\s*FN:(\w+\s*\w*)\b/ ) {
        $name = $1;
    }
    elsif( $line =~ /^\s*TEL;TYPE=CELL;TYPE=PREF:([+|(?:91)]?\d{10})\b
+/ ) {
        $number = $1;
        if( defined($name) && defined($number) ) {
            printf $fh2 "%15s -> %d\n", $name, $number ;
        }
    }    
}

close $fh2 or die "$!";
close $fh or die "$!";
[download]

How about command line parameter checking?

...
my $filename = $ARGV[0];
my ($name, $number);

die "Usage: $0 filename\n" unless $filename; # checking command line p
+arameter
...
[download]

use strict;
use warnings;

my $filename = $ARGV[0];
my ($name, $number);

open my $fh, "<", "$filename" or die "$!";
open my $fh2, ">", "list.txt" or die "$!";

my @matches=();

while(my $line = <$fh>) {

        if (grep { $line =~ $_ } qr/^\s*FN/, qr/\s*TEL/){

                if( $line =~ /^\s*FN:(.*)/ ) {
                  push(@matches,$1);
                }
                elsif( $line =~ /^\s*TEL;TYPE=CELL;TYPE=PREF:(.*)/ ) {
                  push(@matches , $1);
                }
       }
       else{
               next;
       }
}
print $fh2 "@matches" ;

close $fh2 or die "$!";
close $fh or die "$!";
[download]