Re: IO::Select, IO::Pipe, fork, Data loss

Bunch of don'ts:

Don't use ->getlines when using select, use sysread instead.

Don't use non-blocking, it's not needed.

Don't forget to check eval for failure - especially from a partial (non-blocking) read.

Don't forget to define $c_max :)

Don't forget about $child_pid = open(my $fh, "-|") self-forking open if you are just reading from a child.

Comment on Re: IO::Select, IO::Pipe, fork, Data loss

Replies are listed 'Best First'.
Re^2: IO::Select, IO::Pipe, fork, Data loss by Anonymous Monk on Aug 05, 2015 at 19:39 UTC
#!/usr/bin/perl # http://perlmonks.org/?node_id=1137500 use IO::Select; use YAML; use strict; use warnings; $\| = 1; my $sel = IO::Select->new; my (%hash, %id); my @a = map "host$_", 1..9; my $max = 4; while(@a or $sel->count) { if(@a and $sel->count < $max) { my $host = shift @a; if(open my $fh, '-\|') { $id{$fh} = $host; $sel->add($fh); $hash{$id{$fh}} .= "starting $host "; print "running ", $sel->count, "\n"; } else { print "hello from the $host child"; exit; } } elsif($sel->count) { for my $fh ($sel->can_read) { if(0 < sysread $fh, my $buf, 1024) { $hash{$id{$fh}} .= $buf; } else { $sel->remove($fh); close $fh; } } } } print Dump \%hash; [download] See, simpler with forked open instead of IO::Pipe when only reading from the child :)	[reply] [d/l]

Replies are listed 'Best First'.

Re^2: IO::Select, IO::Pipe, fork, Data loss
by Anonymous Monk on Aug 05, 2015 at 19:39 UTC

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1137500

use IO::Select;
use YAML;
use strict;
use warnings;
$| = 1;

my $sel = IO::Select->new;
my (%hash, %id);
my @a = map "host$_", 1..9;
my $max = 4;

while(@a or $sel->count)
  {
  if(@a and $sel->count < $max)
    {
    my $host = shift @a;

    if(open my $fh, '-|')
      {
      $id{$fh} = $host;
      $sel->add($fh);
      $hash{$id{$fh}} .= "starting $host  ";
      print "running ", $sel->count, "\n";
      }
    else
      {
      print "hello from the $host child";
      exit;
      }
    }
  elsif($sel->count)
    {
    for my $fh ($sel->can_read)
      {
      if(0 < sysread $fh, my $buf, 1024)
        {
        $hash{$id{$fh}} .= $buf;
        }
      else
        {
        $sel->remove($fh);
        close $fh;
        }
      }
    }
  }

print Dump \%hash;
[download]

See, simpler with forked open instead of IO::Pipe when only reading from the child :)

[reply]
[d/l]