G'day Helan_Ahmed,

Welcome to the Monastery.

The match operator (see Binding Operators) contains no internal whitespace, i.e. '=~' is correct; '= ~' is incorrect.

Here's how Perl parses that part of the code you posted:

$ perl -MO=Deparse,-p -e '$_= ~/ssId=\s*?(\S+)/'
($_ = (~/ssId=\s*?(\S+)/));
-e syntax OK
[download]

Removing the erroneous whitespace, and Perl now knows what you mean:

$ perl -MO=Deparse,-p -e '$_=~/ssId=\s*?(\S+)/'
($_ =~ /ssId=\s*?(\S+)/);
-e syntax OK
[download]

Adding appropriate whitespace (around the operator) and both Perl and human readers know what you mean:

$ perl -MO=Deparse,-p -e '$_ =~ /ssId=\s*?(\S+)/'
($_ =~ /ssId=\s*?(\S+)/);
-e syntax OK
[download]

[Aside: Please indicate updates at the place where the update was made. I see you mentioned the update elsewhere in the thread but, until I'd read that far, earlier responses to you original post made no sense. See "How do I change/delete my post?" for details and further explanation.]

Update (additional information): As you're new to Perl, the 'perl -MO=Deparse ...' line possibly means little to you. It's explained in B::Deparse.

Second if block

##if ($_=~ /ssId=\s*?(\S+)/)
if ($_=~ /subSnpClass=\s*?(\S+)/)
[download]

Oh sorry I made syntax error, I updated the script, but even when I search for subSnpClass, it print ssId twice

After corrections to these 2 lines

# $_= ~ /ssId=\s*?(\S+)/
$_ =~ /ssId=\s*?(\S+)/

#if ($_= ~ /subSnpClass=\s*?(\S+)/)
if ($_ =~ /subSnpClass=\s*?(\S+)/)
[download]

I got this result

RS_SNPs    subSnpClass3931
    snp
76536062
    snp
[download]

maybe try this

#!perl
use strict;
use warnings;

my $Gene    = 'ds_chY.xml';
my $outfile = 'ID.txt';

open my $out,'>',$outfile or die "Could not open file '$outfile' $!";
print $out "RS_SNPs\tsubSnpClass\n";

open my $in,'<',$Gene or die "Could not open file '$Gene' $!";
while (<$in>){
  
  if ( /ssId=\s*"([^"]+)/ ){
    print $out "$1\t";
  }
  
  if ( /subSnpClass=\s*"([^"]+)/ ){
    print $out "$1\n";
  }
  
}
[download]

poj

That's because you search for 'ssId' twice! You'll have to change that if you want it to do something else.

if ($_= ~/ssId=\s*?(\S+)/)
{ 
 ...
}
if ($_= ~/ssId=\s*?(\S+)/)
{
 ...
}
[download]

Hello Helan

Too be frank: Your posted coded looks like you cobbled it together without really understanding what you're doing. I took the liberty to clean it up somewhat. Request: Just have a look at it and see what could be done differently. The provided code is making some fundamental assumptions about your XML-format and works with the provided input - but I really, really recommend using a true XML-Parser instead.

#!/usr/bin/perl

use strict;
use warnings;
# ^-- Just do it.

my $Gene     = 'ds_chY.xml';
my $filename = 'ID.txt';

open my $fh_i, '<', $Gene
  or die "Cannot open the file '$Gene': $!";
open my $fh_o, '>', $filename
  or die "Could not open file '$filename' $!";
# ^-- use the same style of open() and error message
#     for both file operations
# (I like to put chained and/or conditionals on the next line.)

print {$fh_o} "RS_SNPs\tsubSnpClass\n";
#       ^- use braced filehandles in order to make it explicit we're
#          writing to a file handle

# either use explicit variable for looping:
while (my $line = <$fh_i>) {
    $line =~ s/^\s+//;  # this is probably irrelevant

    # don't write to file immediately - wait a bit

    my ($ssId, $subSnpClass);
    if ( $line =~ /ssId=["](\S*)["]\s/ ) {  # regexp optimization
        $ssId = $1;     # -> no need to s/// and chop
    }
    if ( $line =~ /subSnpClass=["](\S*)["]/ ) {
        $subSnpClass = $1;
    }

    # ...in order to perform a small sanity check
    if (defined $ssId and defined $subSnpClass) {
        print {$fh_o} "$ssId\t$subSnpClass\n";
    }
    elsif (not defined $ssId and not defined $subSnpClass) {
        # nothing
    }
    else {
        print "Data inconsistency detected in line $line\n";
    }
}

# ... or use implicit variable $_:
while (<$fh_i>) {
    s/^\s+//;

    my ($ssId, $subSnpClass);

    if ( /ssId=["](\S*)["]\s/ ) {
        $ssId = $1;
    }
    if ( /subSnpClass=["](\S*)["]/ ) {
        $subSnpClass = $1;
    }

    if (defined $ssId and defined $subSnpClass) {
        print {$fh_o} "$ssId\t$subSnpClass\n";
    }
    elsif (not defined $ssId and not defined $subSnpClass) {
        # nothing
    }
    else {
        print "Data inconsistency detected in line ", $_, "\n";
    }
}
[download]

(The second while loop is useless, because there's no more stuff to be read. It's just an example how the loop could be written in a different manner.)

Please do NOT use:

while (<$fh_i>) {
  if ($_ =~ ...) ...
[download]

...because it's a bit like wearing your pants backwards. Sure you can do it and it keeps your legs warm, but everyone will laugh at you behind your back.

Thanks a lot, it really helped me. could you help me to print also the content between <Observed>C/T</Observed> which is C/T for all of them

Sorry, but no. I won't do that. As I already wrote: This is just meant as an example to improve your understanding of Perl.

If you want more functionality then please implement it on your own. This way you also have a better understanding what goes wrong when it goes wrong. (And since the input format is XML I'm very confident something will go wrong.) You really should not use regular expressions to parse XML - use a real parser instead.

Oh sorry I made syntax error, I updated the script, but even when I search for subSnpClass, it print ssId twice

Please show us a sample of your input file.

I added a sample of input file to my post. Thanks