If you're getting a message about it not being a hash reference, then it means you have something in the slot, but it's not a hash reference. You can check whether a hash slot exists with the perldoc -f exists. Here's a simple bit showing how to check several things out about a hash:

$ cat foo.pl
use strict;
use warnings;

my %hash = (
    foo => undef,
    bar => { a=>7 },
    baz => 'quandary',
);

for my $k ('joe', 'foo', 'bar', 'baz') {
    if (! exists $hash{$k}) {
        print "Key $k does not exist in hash\n";
        next;
    }
    if (! defined $hash{$k}) {
        print "Key $k exists, but value is not defined\n";
        next;
    }
    my $r = ref($hash{$k});
    $r = "SCALAR" if $r eq '';
    print "Key $k exists, refers to ", $r, "\n";
    print "looking up \$hash{$k}{a}: $hash{$k}{a}\n";
}

Roboticus@Waubli ~
$ perl foo.pl
Key joe does not exist in hash
Key foo exists, but value is not defined
Key bar exists, refers to HASH
looking up $hash{bar}{a}: 7
Key baz exists, refers to SCALAR
Can't use string ("quandary") as a HASH ref while "strict refs" in use
+ at foo.pl line 22.
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Check for exists:

if (! exists $hash{$key}){ 
    ...
    next;
}
[download]

In the above, it's possible to just say if (! $hash{$key}), but if the hash key's value has something like 0 or anything else false (or undef), the if will be false.

Check if hash key is another hash:

if (! ref $hash{$key} eq 'HASH'){
    ...
    next;
}
[download]

Now, with that said, you're probably best off showing us a piece of your structure and the code that accesses it. Many times, warnings like this are thrown due to the code accessing the structure is doing something we don't expect, and other times it may be because we are misunderstanding what the structure really is in the first place.

-stevieb

Re-parented this (my own) node from considered duplicate I want to check if a particular hash exists or not and not just the key.

Post the hash you are using. so we can help you better.

From the error message you posted, it seems you are trying to access a data structure as hash reference, but it doesn't hold a reference to a hash.

It might be useful to dump your data structure to figure out what it actually is.

use Data::Dumper;
print(Dumper($datastructure));
[download]

Post us the output of the Dumper() here and tell hash which part you are trying to access.

# load XML into $tree here, then ...
traverse ($tree);

sub traverse {
    my $tree = shift;
    if (ref($tree) eq 'ARRAY') {
        traverse($_) for (@$tree);
    }
    elsif (ref($tree) eq 'HASH' ) {
        while (my ($k, $v) = each %$tree) {
            # process key $k
            traverse($v);
        }
    }
    elsif (!ref($tree)) {
        # process $tree as a scalar here
    }
    else {
        die "unexpected type of reference: " . ref($tree);
    }
}
[download]