Since Perl doesn't support two-dimensional arrays

Um, actually Perl does:

#!/usr/bin/perl
use strict;
use warnings;

my @twoDArray = (
    [1, 2, 3, 4],
    [5, 6, 7, 8],
    [9, 10, 11, 12, 13]
);

# Avoiding indexes
for my $rows (@twoDArray) {
    for my $value (@$rows) {
        print "$value ";
    }
    
    print "\n";
}

print "\n";

# Using indexes
for my $rIdx (0 .. $#twoDArray) {
    for my $vIdx (0 .. $#{$twoDArray[$rIdx]}) {
        print "$twoDArray[$rIdx][$vIdx] ";
    }
    
    print "\n";
}
[download]

Prints:

1 2 3 4 
5 6 7 8 
9 10 11 12 13 

1 2 3 4 
5 6 7 8 
9 10 11 12 13
[download]

In fact Perl supports as many dimensions as you want and actually allows mixtures of arrays, hashes and various scalar types as well in arrays.

... Perl supports as many dimensions as you want and actually allows mixtures of arrays, hashes and various scalar types as well in arrays.

Jenny1990: Please see perldsc, perllol. (Update: Oops, RichardK beat me to one of these — should have read everything before posting!)

---

Give a man a fish:  <%-{-{-{-<

When I was first learning perl, I read that "perl does not support two dimensional arrays". (Sorry I do not remember where) I was confused because I had examples of source code which clearly used them. I now consider the discrepancy to be one of viewpoint. Perl does not have a data type similar to the multidimensional array of other languages. Perl does provide an alternate indexing syntax which allows us to use an array-of-arrays exactly as if it were a two-dimensional array. I do not think it matters how the support is implemented. GrandFather has shown us that it is available and how to use it.
Bill

perldsc - Perl Data Structures Cookbook, is a great reference for complex data structures, it's well worth a read. It contains lots of advice & examples, and should help you with your problem.

BTW, perl ships with lots of documentation, try 'perldoc perl' for a starting point.

Hi Jenny1990, it's hard to follow what you are trying to do. Can you please post a stripped-down version of your code?

You probably need to build up a hash data structure. You could either do a complex SQL query on several tables, or you could build up your data structure as you read the rows from each table.

Your data might look like this after you've built it:

my $measurements = { 
                    'MeasurementA' => {
                                       1 => {
                                             'Date'  => 'DateA',
                                             'Value' => '1A',
                                            },  
                                      },  
                    'MeasurementB' => {
                                       1 => {
                                             'Date'  => 'DateB',
                                             'Value' => '3A',
                                            },  
                                       2 => {
                                             'Date'  => 'DateD',
                                             'Value' => '2A',
                                            },  
                                       3 => {
                                             'Date'  => 'DateE',
                                             'Value' => '5A',
                                            },  
                                      },  
                    'MeasurementC' => {
                                       1 => {
                                             'Date'  => 'DateC',
                                             'Value' => '3A',
                                            },  
                                      },  
                   };
[download]

And then you can use it to produce your report:

foreach my $measurement ( sort keys %{ $measurements } ) { 
  print "Measurement: $measurement\n";
  foreach my $try ( sort keys %{ $measurements->{ $measurement } } ) {
+ 
    print "  Try: $try\n";
    print "    Date:  $measurements->{ $measurement }->{ $try }->{'Dat
+e'}\n";
    print "    Value: $measurements->{ $measurement }->{ $try }->{'Val
+ue'}\n";
  }
}
[download]

Outputs:

Measurement: MeasurementA
  Try: 1
    Date:  DateA
    Value: 1A
Measurement: MeasurementB
  Try: 1
    Date:  DateB
    Value: 3A
  Try: 2
    Date:  DateD
    Value: 2A
  Try: 3
    Date:  DateE
    Value: 5A
Measurement: MeasurementC
  Try: 1
    Date:  DateC
    Value: 3A
[download]

Or,

foreach my $measurement ( sort keys %{ $measurements } ) { 
  print "$measurement -- ";
  foreach my $try ( sort keys %{ $measurements->{ $measurement } } ) {
+ 
    print "$measurements->{ $measurement }->{ $try }->{'Date'}: $measu
+rements->{ $measurement }->{ $try }->{'Value'} ";
    last if $try == scalar keys %{ $measurements->{ $measurement } };
    print " -- ";
  }
  print "\n";
}
[download]

Outputs:

MeasurementA -- DateA: 1A 
MeasurementB -- DateB: 3A  -- DateD: 2A  -- DateE: 5A 
MeasurementC -- DateC: 3A
[download]

But first you'll have to build your data structure.

for (my $i = 0; $i <= $#MeasurementType; $i++) {
    my $toTry = $MeasurementTry[$i];
    while ($toTry) {
        print "$MeasurementType[$i] "
            . "-- "
            . "$MeasurementDate[$i], "
            . "Oops ";
        print --$toTry ? "\t" : "\n";
    }
}
[download]

The last print statement I put in may seem harder to read -- it's a shorthand for the following logic: "decrement $toTry, then print tab if there are still tries left else print cr" - You'll probably have to change that anyway when you re-organise the values array.

use strict;
#use warnings; turned off for redundant printf warning

my @MeasurementType = sort qw(MeasurementA MeasurementB MeasurementC M
+easurementB MeasurementB);
my @MeasurementValue = sort qw(1A 3A 3A 2A 5A);
my @MeasurementTry= sort qw(1 1 1 2 3);
my @MeasurementTime= sort qw(DateA DateB DateC DateD DateE);

my $size = @MeasurementTry - 1;

print ("MeasurementType |   MeasurementValue    | MeasurementTry | Mea
+surementTime\n");
print ("----------------|-----------------------|----------------|----
+------------\n");

for ( my $i = 0 ; $i <= $size ; $i++ ) {
printf ("%-22s %-15s %-9s %-0s\n",
        ("$MeasurementType[$i]\t|", "$MeasurementValue[$i]     \t|", 
        "$MeasurementTry[$i]\t |", "$MeasurementTime[$i]"));
}
[download]

Outputs:

MeasurementType |   MeasurementValue    | MeasurementTry | Measurement
+Time
----------------|-----------------------|----------------|------------
+----
MeasurementA    |         1A            |       1        |      DateA
MeasurementB    |         2A            |       1        |      DateB
MeasurementB    |         3A            |       1        |      DateC
MeasurementB    |         3A            |       2        |      DateD
MeasurementC    |         5A            |       3        |      DateE
[download]