Have a look at Array::Transpose for the column to row transposition once you've read in with Text::CSV (as mentioned above).

Hi VinsWorldcom, The text file has csv data itself. I didnt get why we need to use Text:CSV first and then proceed. We can straight away use Array::Transpose ??

Text::CSV offers a more robust interface than:

my @csv;
while (<$fh>) {
    chomp $_;
    my @p = split /,/, $_;
    push @csv, \@p;
}
[download]

or something like that. If your goal is to be robust, I'd use the module that is solely dedicated to reading that type of data and then another that helps you transform it. Not sure about the JSON output, you're getting a bit out of my league there, but again, if you're looking for robust, readable, supportable code, use the module that's been vetted by all CPAN'ers versus rolling your own.

When you cross-post at many sites, it's polite to advise you've done so.

This saves people from doing work in forming an answer when the question may have already been answered somewhere else.

Hello ash1351,

Here is one way to do it with the help of Data::Table and Cpanel::JSON::XS. There are a few different choices for modules to parse csv files and to emit JSON...I just happen to be familiar with these ones.

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Table;
use Cpanel::JSON::XS;

my $table = Data::Table::fromCSV('data.csv');

my @column_names = $table->header;

foreach my $col_name (@column_names) {
    my @column_values = $table->col($col_name);
    my $json = encode_json(\@column_values);
    print "var $col_name = $json;\n";
}

exit;
[download]

var secid = ["002826","0028262","0028262","0028262","0028262","0028262
+"];
var Initial_shares = ["3777","3777","3777","3777","3777","3777"];
[download]

my @a=();
my @b=();

my @a1=();
my @b1=();
[download]

Whenever you feel the need to declare variables like @a,@b,@c,... or @a1,@a2,... it is almost always better to use a container, specially if you want to extend those items without having to declare @d,@e or @a12,@a13 later on.

This also greatly simplifies your code. You want an array of columns, without having to know how many columns there will be? Use a two-dimensional array, i.e. an array of arrays. This is done with references in perl - see perlref.

open (TXT, "<$filename") || die "Can't open $filename: $!\n";
my @array;

while (my $line=<TXT>) {
    chomp($line);
    my @list = split /,/, $line;
    # now distribute the elements into each column's array
    for ( 0 .. $#list ) {
        push @{$array[$_]}, $list[$_];
    }
}
[download]

Your @array now looks like this:

@array = (
  [
    'secid',
    '002826',
    '0028262',
    '0028262',
    '0028262',
    '0028262',
    '0028262'
  ],
  [
    'Initial_shares',
    '3777',
    '3777',
    '3777',
    '3777',
    '3777',
    '3777'
  ]
);
[download]

Now populate @perl_array with the stringified elements of @array:

my @perl_array;

foreach $array_ref ( @array ) {
    my $colname = shift @$array_ref;
    my $items   = join ",", @$array_ref;
    push @perl_array, "var $colname=[$items]";
}

for ( @perl_array ) {
    print $_,"\n";
}
[download]

Output:

var secid=[002826,0028262,0028262,0028262,0028262,0028262]
var Initial_shares=[3777,3777,3777,3777,3777,3777]
[download]

Adding more columns to your data results in more elements in @perl_array. Using as input

secid,Initial_shares,Char
002826,3777,a
0028262,3777,b
0028262,3777,c
0028262,3777,d
0028262,3777,e
0028262,3777,f
[download]

results in

var secid=[002826,0028262,0028262,0028262,0028262,0028262]
var Initial_shares=[3777,3777,3777,3777,3777,3777]
var Char=[a,b,c,d,e,f]
[download]

And yes, you should use Text::CSV or such as mentioned elsewhere.

You should use Text::CSV to read the data and one of the JSON modules to output it.

Will i be able to do it dynamically ? that is my concern.

Here is my input on it, which I am pretty new to hashes as well so please keep that in mind ;)

use strict;
use warnings;
use Data::Dumper;

my %hash = ();

my $i = 0;

while (<DATA>) {
    chomp;
    my ( $sec_id, $Initial_shares ) = split( /,/, $_ );
    $hash{secid}{$i}   = $sec_id;
    $hash{init_sh}{$i} = $Initial_shares;
    $i++;
}

#print Dumper \%hash;
foreach my $outter_key ( keys %hash ) {
    print "$outter_key => {\n";
    while ( my ( $inner_key, $inner_value ) = each $hash{$outter_key} 
+) {
        print "\t\t" . qq('$inner_key') . " => " . qq('$inner_value') 
+. "\n";
    }
    print "};\n\n";
}

__DATA__
002826,3777
0028262,3777
0028262,3777
0028262,3777
0028262,3777
0028262,3777
[download]

Outputs:

init_sh => {
                '4' => '3777'
                '1' => '3777'
                '3' => '3777'
                '0' => '3777'
                '2' => '3777'
                '5' => '3777'
};

secid => {
                '4' => '0028262'
                '1' => '0028262'
                '3' => '0028262'
                '0' => '002826'
                '2' => '0028262'
                '5' => '0028262'
};
[download]

This method looks like it would be a sure fire way to keep track of what belonged to what as well.

EDIT: I dont know why, but I thought OP was looking for a solution with hashes... anyway on a side note, while I was messing around with this, I did figure out another way to load modules haha;

EDIT: Updated code.

If you use Text::CSV_XS' csv function with the filter attribute, you don't also keep the CSV data and stream the required content right into the arrays:

use 5.14.2;
use warnings;

use Text::CSV_XS qw(csv);

my (@a, @b);
my $aoa = csv (
    in      => *DATA,
    headers => "skip",
    filter  => {
        1 => sub { push @a, $_; 1 },
        2 => sub { push @b, $_; 0 },
        });

{   local $" = ", ";
    say "var secid = [@a]";
    say "var Initial_shares = [@b]";
    }

__END__
secid,Initial_shares
002826,3777
0028262,3777
0028262,3777
0028262,3777
0028262,3777
0028262,3777
[download]

→

var secid = [002826 0028262 0028262 0028262 0028262 0028262]
var Initial_shares = [3777 3777 3777 3777 3777 3777]
[download]

The entries in the filter will be used in ascending order. All but the last should return a true value. The last should return a false value to reject the record: You already stored all required data in the two arrays.

update: Alternatively, you can put everything in a hash:

my %h;
my $aoa = csv (
    in      => *DATA,
    headers => "auto",
    filter  => { 1 => sub { for my $f (keys %_) { push @{$h{$f}}, $_{$
+f} }; 0 }},
    );
[download]

→

{   Initial_shares   => [
        3777,
        3777,
        3777,
        3777,
        3777,
        3777
        ],
    secid            => [
        '002826',
        '0028262',
        '0028262',
        '0028262',
        '0028262',
        '0028262'
        ]
    }
[download]


Enjoy, Have FUN! H.Merijn