See perlretut and Can I use Perl regular expressions to match balanced text?.

But first, think about what you are doing. What you seek to do is not simple. Unless this is a homework assignment, I would reconsider the problem and approach it differently. If you are parsing a known format such as XML or HTML then you should use an existing module. If you are parsing a file you created then you should create it with a tree structure instead.

Agreed. Unbounded nested scoping requires a state machine with a stack. Every time a new scope is encountered, the current state of the machine is pushed onto the stack and when it ends, the saved stated is popped off.

Your spec is pretty minimal, but here's one way to achieve your goal:

#! perl -slw
use strict;
use Data::Dump qw[ pp ];

my $text = do{ local $/; <DATA>; };

my( $n, @scopes ) = 1;

1 while $text =~ s[
    ( \{ [^{}]+ \} )
]{
    push @scopes, $1;
    '_' . $n++ . '_';
}gex;

s[scope (\d+) text][processed text $1]g for @scopes;

$text =~ s[_${ \( $_+1 ) }_]{ $scopes[ $_ ] }eg for reverse 0 .. $#sco
+pes;

print $text;

__DATA__
text text {scope 4 text {scope 2 text {scope 1 text} scope 2 text} sco
+pe 4 text {scope 3 text} scope 4 text } text text
[download]

Output:

C:\test>1139932
text text {processed text 4 {processed text 2 {processed text 1} proce
+ssed text 2} processed text 4 {processed text 3} processed text 4 } t
+ext text
[download]

Processed how?

#!/usr/bin/perl -l

# http://perlmonks.org/?node_id=1139932

use strict;
use warnings;

my $in = 'text text {scope 4 text {scope 2 text {scope 1 text} scope 2
+ text} scope 4 text {scope 3 text} scope 4 text } text text';

print $_ = $in;

print while s/{[^{}]*}/PROCESSED/;
[download]

0.  text {scope 4 {scope 2 {scope 1} scope 2} scope 4 {scope 3} scope 
+4} text

1.  text {scope 4 {scope 2 -change1- scope 2} scope 4 {scope 3} scope 
+4} text

2.  text {scope 4 - - - -c h a n g e 2- - - - scope 4 {scope 3} scope 
+4} text

3.  text {scope 4 - - - -c h a n g e 2- - - - scope 4 -change3- scope 
+4} text

4.  text - - - - - - - - - - - - -c h a n g e 4- - - - - - - - - - - -
+ - text
[download]

(Update: I suppose that if there were interactions from one step to the next - e.g. if a substitution at step 1 either creates or eliminates a condition that affects what happens in a later stage - then it becomes a more complicated business, posing greater challenges for maintenance.)

The best advice already given is use a template module. If you decide not to, I'd use substr rather than regular expressions

You can use index to find closing braces, the first one you find will be the close of the innermost scope. Then use the position you found with rindex to find the opening brace of that scope. You can extract the data with substr.

You can process the extract and then use substr to replace it and the braces in the original data.

Instead of processing the extract and replacing it, this snippet uses substr to replace the braces. This means you won't continually work on the same scope. It prints the bits it extracted as $extract so you can see it works on scopes in the correct order.

You need to make sure that whatever you substitute in doesn't have braces.

#!/usr/bin/perl

use strict;
use warnings;

my $data = <DATA>;
chomp $data;

while () {
    my ($rpos, $lpos) = (0, 0);

    $rpos = index($data, "}", $rpos);
    last if $rpos < 0;

    $lpos = rindex($data, "{", $rpos);
    last if $lpos < 0;

    # $lpos + 1 so we don't extract the the {
    # -1 at the end to exclude the }
    my $extract = substr($data, $lpos + 1, $rpos - $lpos - 1);

    # get rid of these braces.
    substr($data, $lpos, 1) = "<";
    substr($data, $rpos, 1) = ">";

    # if you wanted to replace the entire section including braces
    # substr($data, $lpos, $rpos - $lpos + 1) = "<>";

    print "|${extract}|\n";
}

print "|${data}|\n";

__DATA__
text text {scope 4 text {scope 2 text {scope 1 text} scope 2 text} sco
+pe 4 text {scope 3 text} scope 4 text } text text
[download]

|scope 1 text|
|scope 2 text <scope 1 text> scope 2 text|
|scope 3 text|
|scope 4 text <scope 2 text <scope 1 text> scope 2 text> scope 4 text 
+<scope 3 text> scope 4 text |
|text text <scope 4 text <scope 2 text <scope 1 text> scope 2 text> sc
+ope 4 text <scope 3 text> scope 4 text > text text|
[download]

In addition, may I suggest that you consider using an existing templating tool, such as Template::Toolkit?   Although often used for creating HTML pages, it can in fact be used for anything.   Although you can “roll your own” solution here, maybe this is an all-around better way to do it.   Much more bang for your buck, and nothing to create.