Hello wangruonan,

Your code has the following skeletal form:

my @headers;

for $a (@list)
{
    open(my $data, ...);

    while (my $line = <$data>)
    {
        while (my $fields = $csv->getline( $data ))
        {
            push @headers, $fields->[$a];
        }
    }

    print LOG $headers[2], "\t";
    close $data;
}
[download]

The obvious problem here is that once @headers contains at least 3 elements, the output will always be the same, viz., the third element!

But it’s also important to note that reading from the filehandle $data directly — my $line = <$data> — and via getline — my $fields = $csv->getline( $data ) — is a logic error. You shouldn’t need the outer while loop; re-write the inner one to traverse the whole file.

Hope that helps,

Update: The OP was completely changed while I wrote this reply, including the subject. OP below. My answer to the revised question further below.

Original post:

#!/usr/local/bin/perl
use strict;
use warnings;

my $i=1;

my @array = (34,543,754,5432,865,623,8635,5324,62,8654);
my @list = (1, 3, 5, 8);


foreach $a(@list){
 print "foreach print value of a: $a\n";
while ($i) {
  print "while print value of a: $a\n";
  $i=$i-1;
  print $array [$a], "\n";
  }
}
[download]

foreach print value of a: 1
while print value of a: 1
543
foreach print value of a: 3
while print value of a: 3
5432
foreach print value of a: 5
while print value of a: 5
623
foreach print value of a: 8
while print value of a: 8
62
[download]

Use for:

my $value = $array[$_] for @list;
[download]

#!/usr/bin/perl
use strict;
use warnings;
use feature qw/ say /;
use Data::Dumper;

my @array = (34,543,754,5432,865,623,8635,5324,62,8654);
my @list = (1, 3, 5, 8); 

say "\$a: $_ \$array[$_] $array[$_]" for @list;

__END__
[download]

$ perl 1140597.pl
$a: 1 $array[1] 543
$a: 3 $array[3] 5432
$a: 5 $array[5] 623
$a: 8 $array[8] 62
$
[download]

Use Text::CSV_XS::fragment():

my @rows = $csv->fragment( *DATA, "col=11;15;18" );
[download]

#!/usr/bin/perl
use strict;
use warnings;
use feature qw/ say /;
use Text::CSV_XS;

my $csv = Text::CSV_XS->new( { binary => 1, auto_diag => 1 } );

my $wanted = join ';', ( 11, 15, 18 );

foreach my $row ( @{ $csv->fragment( *DATA, "col=$wanted" ) } ) { 
  say "@{ $row }"; 
}


__DATA__ 
A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z
z,y,x,w,v,u,t,s,r,q,p,o,n,m,l,k,j,i,h,g,f,e,d,c,b,a
[download]

$ perl 1140597-2.pl
K O R
p l i
$
[download]