pack and unpack are, as a matter of fact a way to achieve what you want although it's not done in one step:
perl -e 'print join " ", map { chr(ord('A')+eval "0b$_") }  unpack "(A5)*", unpack "B*", pack "H*", "139686DA20C1"'

The first transformation is pack "H*", $str where the hexadecimal numbers are turned into binary data.

Then unpack "B*", $str; turns the binary data into a string consisting of the characters '0' and '1'.

unpack "(A5)*", $str; is one of the many ways to split a string every five characters.

Then, packing and unpacking those 5 bits strings into numbers would have been possible, but eval "0b$str" just does that in one step.
chr($nb + ord('A')) is the character at the position "position of A" + $nb. Which is what you want:)

Welcome G109B,

I think you will find it easier to use binary strings for your project. To get you started:

perl -e '$h=pack("H*","139686DA20C1");$b=unpack("B*",$h);print length(
+$b)," $b\n";'
[download]

Then use 'substr' to get 5 binary digits at a time.

while( $b )
{ print substr($b,0,5,"");
}
[download]

Why are you using Base 5, when the rest of the world uses binary?

Regards...Ed

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1141773

use strict;
use warnings;

print handlingbinary( "139686DA20C1" ), "\n";

sub handlingbinary
  {
  return join '', ('A'..'Z')[ map { oct "0b$_" }
    (unpack 'B*', pack 'H*', shift()) =~ /.{5}/g ]
  }
[download]

Prints:

COLINWRAY
[download]

Hi Colin! (Am I right? If not, let me know :)

I missed the part about having to generate these strings, here you go:

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1141773

use strict;
use warnings;

my $answer = handlingbinary( "139686DA20C1" );
print "$answer\n";

print tofivebit( 'ANONYMOUS MONK' ), "\n";
print tofivebit( 'COLINWRAY' ), "\n";


sub handlingbinary
  {
  return join '', ('A'..'Z')[ map { oct "0b$_" }
    (unpack 'B*', pack 'H*', shift()) =~ /.{5}/g ]
  }

sub tofivebit
  {
  uc unpack 'H*', pack 'B*',
    shift() =~ tr/A-Z//cdr =~ s/(.)/ sprintf "%05b", ord($1) - ord('A'
+) /ger;
  }
[download]

Many thanks to the three responders, and yes you got it right. The code snippets contain some very welcome insights into this (sometimes) irritating language - at least to an old (retired) C/C++ programmer.

Why 5 bit ? - not my choice, not my firmware which requires it, but surely to conserve space. There is some 6 bit later in the string because they needed to include digits.

Hex is a way of life for me.

Colin