use warnings;
use strict;

my $path = "XX.YY.ZZ";
my $s    = "(ABC | (~dEf & hIJ)) & ~LMn";
$s =~ s/([a-z]+)/$path.$1/gi;
print "$s\n";

__END__

(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hIJ)) & ~XX.YY.ZZ.LMn
[download]

Verilog equation?

works great and yes it's verilog thank you

There are strings that I don't need appending the $path, such as "else" "if" "1'b0", is there a way to add this to the expression or do I have to split ' ' and check each string? Also, how do I treat "ABC_DEF" "b_C_D_E" as one word and append $path only to the beginning of the string? Thanks

Parsing Verilog is not trivial. Consider Verilog-Perl

Including _ and ignoring some keywords...

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1142266

use strict;
use warnings;

my $path = "XX.YY.ZZ";
my $s    = "(ABC | (~dEf & hIJ)) & ~LMn if foo while bar";
my %ignore = map { $_, $_ } qw( if while for );

(my $answer = $s) =~ s/(\w+)/$ignore{$1} || "$path.$1"/ge;

print "$answer\n";
[download]

Another variation:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $path = 'XX.YY.ZZ';
 my ($ignore) =
   map qr{ (?: $_) (?! [[:alpha:]]) }xms,
   join q{ | },
   qw(if while for)
   ;
 ;;
 my $s = '(ABC | (~dEf & hIJ)) & ~LMn if form while i';
 ;;
 my $expected = '(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hIJ)) & ~XX
+.YY.ZZ.LMn if XX.YY.ZZ.form while XX.YY.ZZ.i';
 print qq{expected: '$expected'};
 ;;
 $s =~ s{ (?<! [[:alpha:]]) (?= [[:alpha:]]) (?! $ignore) }
        {$path.}xmsg;
 print qq{     got: '$s'};
 $s eq $expected or die 'FAILED';
 print 'a-ok';
"
expected: '(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hIJ)) & ~XX.YY.ZZ
+.LMn if XX.YY.ZZ.form while XX.YY.ZZ.i'
     got: '(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hIJ)) & ~XX.YY.ZZ
+.LMn if XX.YY.ZZ.form while XX.YY.ZZ.i'
a-ok
[download]

Update: Just took another look at Re^2: Appending strings and realized solution above doesn't cover "1'b0" or "ABC_DEF". These could be included, but I'm sure that wouldn't be the end of it. Yeah, a real Verilog parser looks like the best bet.

Perhaps you could use positive and negative look-arounds with pos to find where you want to insert $path. and then work back along the string inserting with the 4-argument form of substr.

use strict;
use warnings;

use 5.014;

my $path   = q{XX.YY.ZZ};
my $str    = q{(ABC | (~dEf & hI_J)) & ~LMn if ~xYz};

# Make a compiled regex of an alternation of the terms to exclude.
#
my $rxExcl = do {
   my @excl = qw{ if else 1'b0 };
   local $" = q{|};
   qr{(?:@excl)};
   };

my @posns;
push @posns, pos $str
   while $str =~ m{(?x)   # Use extended regex syntax
      (?<! [A-Za-z_] )    # Match at a point not preceded by 
                          #    letters or underscore
      (?=  [A-Za-z_] )    # And which is followed by letters
                          #    or underscore
      (?!  $rxExcl )      # But not followed by any our terms
                          #    to exclude
      }g;

substr $str, $_, 0, qq{$path.} for reverse @posns;
say $str;
[download]

Outputs

(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hI_J)) & ~XX.YY.ZZ.LMn if ~X
+X.YY.ZZ.xYz
[download]

I hope this is useful.

Update: Added comment above $rxExcl creation and comments to the string matching regex to clarify what it is doing.

Hi, I added "end" to the excl list and the string beginning with endxxx is not getting substituted. To exclude "end" but not "end" that's followed by strings or symbol or numbers, do I do excl = qw{ end\b ) ? thanks

If I have understood correctly what you require, use the "word boundary" asserstion (\b), see perlre.

use strict;
use warnings;

use 5.014;

my $path   = q{XX.YY.ZZ};
my $str    = q{(ABC | (~dEf & hI_J & endxxx)) & ~LMn if ~xYz end};

# Make a compiled regex of an alternation of the terms to exclude.
#
my $rxExcl = do {
   my @excl = qw{ if else 1'b0 end };
   local $" = q{|};
   qr{(?x) (?: @excl ) \b};
   };

my @posns;
push @posns, pos $str
   while $str =~ m{(?x)   # Use extended regex syntax
      (?<! [A-Za-z_] )    # Match at a point not preceded by 
                          #    letters or underscore
      (?=  [A-Za-z_] )    # And which is followed by letters
                          #    or underscore
      (?!  $rxExcl )      # But not followed by any our terms
                          #    to exclude
      }g;

substr $str, $_, 0, qq{$path.} for reverse @posns;
say $str;
[download]

The output.

(XX.YY.ZZ.ABC | (~XX.YY.ZZ.dEf & XX.YY.ZZ.hI_J & XX.YY.ZZ.endxxx)) & ~
+XX.YY.ZZ.LMn if ~XX.YY.ZZ.xYz end
[download]

I hope this is what you want.

Cheers,

JohnGG

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1142266

use strict;
use warnings;

my $path = "XX.YY.ZZ";
my $s    = "(ABC | (~dEf & hIJ)) & ~LMn";

print $s =~ s/(\w+)/$path.$1/gr, "\n";
[download]

I tried it and it says : syntax error at t line 80, near "s/(\w+)/$path.$1/gr" Execution of t aborted due to compilation errors.

It may be the /r modifier to s///, which was added in perl version 5.14: Regular Expressions. What perl version are you on?

perl -v
[download]

#!/usr/bin/perl

# http://perlmonks.org/?node_id=1142266

use strict;
use warnings;

my $path = "XX.YY.ZZ";
my $s    = "(ABC | (~dEf & hIJ)) & ~LMn";

(my $answer = $s) =~ s/(\w+)/$path.$1/g;

print "$answer\n";
[download]

Tweaked for older perls.