I like AppleFritter’s approach. But, in the spirit of TMTOWTDI, here’s another, which builds the required regex via a subroutine call:

#! perl
use strict;
use warnings;

my %searches =
(
    bar => " bar  \n\n",
    foo => "  foo  c  \n",
);

for (sort keys %searches)
{
    print "$_: ", $searches{$_} =~ re($_) ? 'match' : 'no match', "\n"
+;
}

sub re
{
    qr{ ^ \s* $_[0] \s* $ }x;
}
[download]

Output:

23:06 >perl 1402_SoPW.pl
bar: match
foo: no match

23:06 >
[download]

Hope that helps,

If you're doing a lot of these tests for different values of "abc", I'd suggest just trimming the whitespace once and then working with the trimmed string:

# ...

use String::Trim;

while(<>) {
    trim;

    given($_) {
        when("abc") {
            say "Got 'abc'!";
        }
        when("cmc") {
            say "Got 'cmc'!";
        }
        when("uep") {
            say "Got 'uep'!";
        }
    }
}
[download]

If you're looking to do more complicated processing that nonetheless involves a lot of boilerplate, you could build a list of regular expressions on-the-fly:

sub got_abc {
    say "Got 'abc'!";
}

sub got_cmc {
    say "Got 'cmc'!";
}

sub got_uep {
    say "Got 'uep'!";
}

sub got_a3 {
    say "Got 'a{3}'!";
}

my %interesting = (
    "abc"       => \&got_abc,
    "cmc"       => \&got_cmc,
    "uep"       => \&got_uep,
    "a{3}"      => \&got_a3,
);

# add boilerplate
my %tests = map {
        qr/^\s*$_\s*$/ => $interesting{$_}
    } keys %interesting;

# process data and apply tests
while(<>) {
    chomp;

    foreach my $test (keys %tests) {
        $_ =~ $test and &{ $tests{$test} };
    }
}
[download]

All

I like this approach, AppleFritter, but it could perhaps be made slightly simpler (or maybe not simpler but only more concise):

use strict;
use warnings;
use 5.014;

my %interesting;
for (qw/ abc cmc uep a{3}/) {
    $interesting{$_} = sub { say "got '$_'!"};
}


# process data and apply tests
for (@ARGV) {
    foreach my $test (keys %interesting) {
        /^\s*$test\s*$/ and $interesting{$test}->();
    }
}
[download]

Running it:

$ perl regexes.pl abc uep cmc aaa foo bar
got 'abc'!
got 'uep'!
got 'cmc'!
got 'aaa'!
[download]

Thanks very much Athanasius and AppleFritter, dynamically building the regexes was the piece of inspiration I was missing :)