Your code fails because it assigns a single scalar value to the lvalue list produced from a hash an array slice. Only one of the elements in the slice will be populated. To populate each element, you can use the x operator in list context.

my @a;
@a[2..5] = (2)x4;
[download]

...or, using map

@a[2..5] = map 2, 2..5;
[download]

...or, using a foreach loop...

$a[$_] = 2 for 2..5;
[download]

There are many other ways to do it as well. Just pick the one that is easiest to read.

[This post is obsolete]

@a[2..5] is an array slice, not a hash slice. @h{'a','b'} would be a hash slice.

Thanks for finding a typo. Fixed.




Dave

Hello bagyi,

You’re right, it’s not working, but you don’t need to use strict to see that:

23:34 >perl -MData::Dump -wE "my @a = ('a'..'j'); @a[2..5] = 2; dd \@a
+;"
["a", "b", 2, undef, undef, undef, "g" .. "j"]

23:35 >
[download]

(Assigning 2 here is equivalent to assigning a list with 2 as the only element. The missing elements default to undef.)

Slices are documented in perldata#Slices.

Hope that helps,

Assigning 2 here is equivalent to assigning a list with 2 as the only element.

That's not right. It's not equivalent to assigning to a list; it is assigning a list. That should read "You are assigning a list consisting of 2 as its only element." I believe you think that @a=2 and @a=(2) are different, but they aren't. Parens don't create lists.

Hello ikegami,

I had to think carefully about this, but of course you’re right. Without parentheses:

13:54 >perl -MData::Dump -wE "my @c = 2, 3; dd \@c;"
Useless use of a constant (3) in void context at -e line 1.
[2]

16:15 >
[download]

the assignment occurs first, because the precedence of the assignment operator is higher than that of the comma operator. So the fact that assignment to an array puts the right-hand side into list context is irrelevent here. With scalar context imposed instead:

16:35 >perl -wE "my $c = 2, 3; say $c;"
Useless use of a constant (3) in void context at -e line 1.
2

16:36 >perl -wE "my $c = (2, 3); say $c;"
Useless use of a constant (2) in void context at -e line 1.
3

16:36 >
[download]

the parentheses act only to change the order of evaluation, because parenthesized expressions (“terms”¹) have the highest precedence. So in a standard array assignment:

16:36 >perl -MData::Dump -wE "my @c = (2, 3); dd \@c;"
[2, 3]

16:36 >
[download]

the assignment to an array puts the RHS into list context; the parentheses create a term; and within that term, the comma operator is “just the list argument separator, and inserts both its arguments into the list.”² I think that makes sense. :-)

Thanks for the clarification,

¹perlop#Terms-and-List-Operators-(Leftward).
²perlop#Comma-Operator.

Athanasius <°(((>< contra mundum

Iustus alius egestas vitae, eros Piratica,

You can use the list multiplier.

$ 
perl -Mstrict -Mwarnings -MData::Dumper -E '
> my @arr = q{a} .. q{j};
> my $low = 2;
> my $high = 5;
> @arr[ $low .. $high ] = ( 2 ) x ( $high - $low + 1 );
> print Data::Dumper->Dumpxs( [ \ @arr ], [ qw{ *arr } ] );'
@arr = (
         'a',
         'b',
         2,
         2,
         2,
         2,
         'g',
         'h',
         'i',
         'j'
       );
$
[download]