Store file 1 in a hash, with the keys being the comparison key between files. Then read file 2, and modify your hash values for each item in file 2. You could either keep in the hash items that are common to the first two files, and then use it as a test for file 3; or you could implement each hash value as a counter, and output any hash key where the counter reaches 3.

I am new to Perl, would you show me an example of the code I would need to add to my existing code?

Hi,

this is a simplified version checking 3 files:

use strict;
use warnings;

my %result;

open my $A, "<", "file1" or die "could not open file1 $!";
while (<$A>) {
    chomp;
    my $key = (split /\t/, $_)[0];
    $result{$key} = 1;
}
close $A;
open my $B, "<", "file2" or die "could not open file2 $!";
while (<$B>) {
    chomp;
    my $key = (split /\t/, $_)[0];
    $result{$key}++;
}
close $B;
open my $C, "<", "file3" or die "could not open file3 $!";
while (<$C>) {
    chomp;
    my $key = (split /\t/, $_)[0];
    if ($result{$key} == 2) { # this key has been seen in both previou
+s files
        print "Line with $key is present in all three files\n";
    }
}    
close $C;
[download]

The value in the %result hash is basically a counter saying how many times you've seen the key. If you find in file3 a key that has already been seen twice, then the key is present in all 3 files. Please note that this assumes that the key cannot be more than once in file2, but only rather small changes would be required to take this possibility into account.

Update: when reading your answer, I only reread the narrative of your original post, without looking at the file samples. I assumed above that all your three files had the same structure, but only see now that they don't. A few minor changes are needed to cope with the actual structure of your files, but I guess that I still gave you the general idea of the solution.

It's generally good form to indicate if you've Crossposted to Stack Overflow and Unix & Linux Stack Exchange to prevent duplication of effort.

The answer I posted on Stack Overflow was:

    #!/usr/bin/env perl
    use strict;
    use warnings;
    use Data::Dumper;
    
    #read file1 into a hash - but invert is it's value => key instead:
    #          'CKEIFJ' => 'cmr03lsp',
    # etc.  
    open( my $file1, '<', "file1.txt" ) or die $!;
    my %file1_content = map { reverse split } <$file1>;
    close($file1);

    print Dumper \%file1_content;
    
    #read file 2 - read keys, store the values. 
    #split _2_ fields, so we keep both numbers as a substring:
    #e.g.:
    #          'cmr03lsp' => '60 70
    #',

    open( my $file2, '<', "file2.txt" ) or die $!;
    my %file2_content = map { split( " ", $_, 2 ) } <$file2>;
    close($file2);

    print Dumper \%file2_content;    
    
    #then iterate file 3, checking if:
    #file1 has a matching 'key' (but inverted - as a value) 
    #file2 has a cross reference. 
    open( my $file3, '<', "file3.txt" ) or die $!;
    while ( my $line = <$file3> ) {
        chomp $line;
        if (    $file1_content{$line}
            and $file2_content{ $file1_content{$line} } )
        {
            print
                "$file1_content{$line} $line $file2_content{$file1_con
+tent{$line}}";
        }
    }
    close($file3);
[download]

Which prints (aside from Dumper diag content):

fji01dde AIDJFMGKG 25 30
cmr03lsp CKEIFJ 60 70
[download]

as requested

If you files are sorted one, you can use linux command comm to find the common lines from all the three files,

    -1 : suppress lines unique to FILE1
    -2 : suppress lines unique to FILE2
    -3 : suppress lines that appear in both files