You have issues with your initial data:

• Assigning an arrayref to an array: @data = [...]
• Unterminated string: "Main Street,
• Failure to separate array elements: @data = [[...][...][...]]

I strongly recommend that you use the strict and warnings pragmata in all your code.

There's documentation on complex data structures. These may be a good place to start:

• perldsc - Perl Data Structures Cookbook
• perllol - Manipulating Arrays of Arrays in Perl

I've had to make some changes to your initial data; however, the following is probably close to what you want.

#!/usr/bin/env perl

use strict;
use warnings;

use Data::Dump;

my @data = (
    [ "JOHN JR", "10/30/2011", "Main Street"],
    [ "JOE DOE", "11/30/1999", "Broke Street"],
    [ "MARY DEE", "06/01/2014", "Pearl Street"]
);

my @AoH;

@{$AoH[@AoH]}{qw{NAME DOB ADDRESS}} = @$_ for @data;

dd \@AoH;
[download]

Output:

[
  { ADDRESS => "Main Street", DOB => "10/30/2011", NAME => "JOHN JR" }
+,
  { ADDRESS => "Broke Street", DOB => "11/30/1999", NAME => "JOE DOE" 
+},
  { ADDRESS => "Pearl Street", DOB => "06/01/2014", NAME => "MARY DEE"
+ },
]
[download]

• @data is an array, but is being assigned an array-REF. Use Parens(), instead of square brackets[] for the outermost delimiter
• the "for" statement aliases $_ to each element. So in you case, you should be using $_ as the index, instead of your hard-coded "1" and "2"
• A perl programmer would prefer "for (@data)" instead of "for (0..$#data)"

The data was a Dump from the array @data, but how you were saying, how would you use "$_" instead of assigning or hard-code "1" and "2" ... to the code?


my @data = ( ["John","10/30","Main Street"],
             ["Mary","6/1","Oak Street"]
         # more data here
        );
      
foreach (@data) {
  push @AoH, { NAME => $_,
               DOB  => $_,
           ADDRESS => $_,
         }
}
[download]

Thanks!

I think your data structure is not what you intend. Your @data has only 1 row (an array ref), instead of 3 rows, each one an array.

Try instead (as NetWallah suggests):

@data = ( ["John","10/30","Main Street"],
          ["Mary","6/1","Oak Street"] );

foreach my $aref (@data) {
  push @AoH, { NAME => $aref->[0], 
...
[download]

You're putting a number into $row on each iteration over data, and then not using it. It's more idiomatic to put each element of @data into $row, then work on that.

for my $row (@data){
    push @aoh, {
                name => $row->[0],
                dob => $row->[1],
                addr => $row->[2],
              };
}
[download]

PS: Your @data array is corrupt. First, you're missing a closing double-quote, and further, you create an array and then immediately assign an array reference to it as it's first element. Please ensure that your data and code compile properly before posting it, unless of course that's the specific problem you don't understand. For an array, you use parens, like so: my @array = (1, 2, ...);

try this:

use strict;
use warnings;
use Data::Dumper;

my @data =
(
    [
      "JOHN JR",
      "10/30/2011",
      "Main Street",
    ],
    [
      "JOE DOE",
      "11/30/1999",
      "Broke Street",
    ],
    [
      "MARY DEE",
      "06/01/2014",
      "Pearl Street",
    ],
);

my @AoH;

for my $row (@data) {
    push @AoH, { NAME => $row->[0], DOB => $row->[1], ADDR => $row->[2
+]};
}

print Dumper \@AoH;
[download]

$VAR1 = [
          {
            'NAME' => 'JOHN JR',
            'DOB' => '10/30/2011',
            'ADDR' => 'Main Street'
          },
          {
            'NAME' => 'JOE DOE',
            'DOB' => '11/30/1999',
            'ADDR' => 'Broke Street'
          },
          {
            'NAME' => 'MARY DEE',
            'DOB' => '06/01/2014',
            'ADDR' => 'Pearl Street'
          }
        ];
[download]