Hello Tiarcon, and welcome to the Monastery!

Just letting you know that you don’t have to use regular expressions for this. has dedicated modules for reading email. For example:

#! perl
use strict;
use warnings;
use Email::Simple;

my $file = 'YourEmailHere.eml';

open(my $fh, '<', $file)
    or die "Cannot open file '$file' for reading: $!";

my $text = do { local $/; <$fh>; };

close $fh
    or die "Cannot close file '$file': $!";

my $email   = Email::Simple->new($text);
my $from    = $email->header('From');
my $subject = $email->header('Subject');

print "FROM:    $from\n";
print "SUBJECT: $subject\n";
[download]

See Email::Simple.

Hope that helps,

Thank you so much, I will give it a go rgds Tony

When do you think your line contains both, From: and Subject:? You will need to correct your logic.

You're basically looking for "From" and "Subject" on the same line, which usually does not occur in emails. Change your logical and to a logical or, and you'll match lines having "From" and lines having "Subject".

In other words, try to change:

while (my $line = <$fh>){ 
    if ($line =~ /From\:/ && $line =~ /Subject\:/) { 
        print $line; 
    } 
}
[download]

while (my $line = <$fh>){ 
    if ($line =~ /From\:/ or $line =~ /Subject\:/) { 
        print $line; 
    } 
}
[download]

while (my $line = <$fh>){ 
    if ($line =~ /From:/ or $line =~ /Subject:/) { 
        print $line; 
    } 
}
[download]

The regex approach needs to look for the "From:" and "Subject:" (and other field labels) only when they appear at the beginning of a line, and it can stop reading input as soon as all the desired fields are found.

my @fields = qw/From: Subject:/;  # you can add more if/when you want
my $field_regex = join( "|", @fields );
my @field_lines;

while (<$fh>) {
    push( @field_lines, $_ ) if ( /^(?:$field_regex) / );
    last if @field_lines == @fields;
}
push @field_lines, "";

print join( "\n", sort @field_lines );
[download]

(updated to include parens around the args for the first "push" call, just because I like using parens around function args)

my @fields = qw/From: Subject:/;  # you can add more if/when you want
my $field_regex = join( "|", @fields );
[download]

I would change the second line to use quotemeta:

my @fields = qw/From: Subject:/;  # you can add more if/when you want
my $field_regex = join( "|", map { quotemeta($_) } @fields );
[download]

It may be unneeded for From: and Subject:, but code may change over time, and adding quotemeta now prevents future bugs.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

Actually, I wouldn't recommend quotemeta in tasks like this. It's seldom or never the case that regex-magic characters will be needed as literals in the patterns being conjoined, but even if this comes up, it can still be better to escape them explicitly as needed (when assigning to the array), and allow some strings to use regex-magic where appropriate:

my @fields = ('From: ', 'Subject: ', 'Thread-\w+: ', 'What-if-there\'s
+-a-qmark\?');

# 3rd element matches "Thread-Topic: ", "Thread-Index: ", etc.
[download]

Obviously, in a context where strings are coming from a potentially tainted source (i.e. not from the source code itself), one must weigh the relative risk/benefit and coding-effort/ease-of-use trade-offs of prohibiting vs. allowing (and taint-checking) regex metacharacters in applications like this.

RFC 2822 seems to state the "Subject:" and other keywords are case-INsensitive

... and to make things worse, "2.2.3. Long Header Fields" allows to wrap lines so that the content is split over several lines. This is a single logical header line, split over several physical lines:

Subject: Mail
 parsing looks
 simple until you
 have 
 read 
 the 
 RFCs
[download]

Additionally, RFC2047 allows encoding of non-ASCII characters.

Any mail parser should be able to handle that, too.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)