I suspect that you are confusing perl's reference with C's pointer. Perl's reference-to-an-array is exactly what its name implies. It really is of no concern to you what it actually contains or how it works. It does not make any sense to use it in an arithmetic expression.

Perl does not have a data type "multi-dimensional-array". Perl simulates it very well with the structure known as an "array-of-arrays". (This is actually an array of references each of which refers to an array.) Perl provides a syntax with multiple indicies to conveniently access individual elements of this structure. You do not know or care where the individual arrays are stored. You have a reference to each one.

I doubt that your data is stored correctly. I cannot be sure without a reasonable sample of your data.

I am also running out of memory before the loop completes.

What is your idea of $aref in that loop that bombs off? Is it an integer, or an array reference? What it the result of adding 1 to an array reference? or 2 ? What happens to an array (or array reference) if you index it with the result of that addition?

my $aref = [];
print $aref,"\n";
print $aref + 1,"\n";
print $aref + 2,"\n";
print "mem: ",qx{ps -o vsz= $$};
$aref[$aref +2] = "foo";
print "mem: ",qx{ps -o vsz= $$};
__END__
ARRAY(0xf5dba0)
16112545
16112546
mem:  28964
mem: 154844
[download]

By converting the hexadecimal address of $aref to integer - this is what happens if you add an integer to it - and using it then as an index, you extend @data and pre-allocate slots, each containing a NULL value. If the address of $aref is high enough, your program hits the memory limit of your machine.

Yes! You are right. Thank you for catching that error. I was adding index value to array reference. How can I change my for loop to make it work?

The "Perlish" way to iterate element-by-element over an array is:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @array = qw(zero one two three);
 ;;
 for my $element (@array) {
   print qq{element '$element'};
   }
"
element 'zero'
element 'one'
element 'two'
element 'three'
[download]

If each "element" of  @array is actually an array reference, you might then need to iterate in turn over the referenced array in similar fashion:

c:\@Work\Perl\monks>perl -wMstrict -le
"my @array = (
   [ 1, 2, 3,    ],
   [ 'v' .. 'z'  ],
   [ qw(one two) ],
   );
 ;;
 for my $arrayref (@array) {
   for my $element (@$arrayref) {
     printf qq{'$element' };
     }
   print '';
   }
"
'1' '2' '3'
'v' 'w' 'x' 'y' 'z'
'one' 'two'
[download]

Please see perldsc for more info and examples.

---

Give a man a fish:  <%-{-{-{-<

You really should be using a module to process CSV. Using Text::CSV for example turns your "parsing" code into:

my $csv = Text::CSV->new();
my @data = @{$csv->getline_all($in_ph)};
[download]

and as a side benefit handles commas in the data and strings with line breaks in them. Maybe your data doesn't have such wayward content, but it's sure nice to know the whole script won't fail if it does.

If your data file was huge you might want to handle it record by record instead of loading the whole lot into memory up front. Your code then becomes something like:

my $csv = Text::CSV->new();

while (my $aref = $csv->getline($in_ph)) {
    ...
}
[download]