in reply to Need help with node names for creating header line

Use the ->name method to retrieve the tag name. 
#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use XML::Twig;

my $input_xml = '<?xml version="1.0" encoding="UTF-8"?>
<response>
    <result>
        <u_service_catalog>true</u_service_catalog>
        <u_chg>false</u_chg>
        <virtual>false</virtual>
        <u_inc>false</u_inc>
        <u_ci_id>B</u_ci_id>
    </result>
    <result>
        <u_service_catalog>true</u_service_catalog>
        <u_chg>false</u_chg>
        <virtual>false</virtual>
        <u_inc>false</u_inc>
        <u_ci_id>C</u_ci_id>
    </result>
    <result>
        <u_service_catalog>true</u_service_catalog>
        <u_chg>false</u_chg>
        <virtual>false</virtual>
        <u_inc>false</u_inc>
        <u_ci_id>A</u_ci_id>
    </result>
</response>';

my $field= $ARGV[0] || 'u_ci_id';
my $twig = 'XML::Twig'->new;
$twig->xparse($input_xml);

my $root = $twig->root;
my @records = $root->children;

my @sorted = sort {     $b->first_child( $field)->text
                    cmp $a->first_child( $field)->text
                } @records;

for my $record (@sorted) {
    my @info_tags = $record->children;
    my @data;

    for my $info_tag (@info_tags) {
        push @data, [ $info_tag->name, $info_tag->text ];
    }
    say join ',', map $_->[0] . ': ' . $_->[1], @data;
}

[download]

push @data, [ $info_tag->name, $info_tag->text ]; stores a two element array to the @data, so when printing it, you have to dereference it (that's what $_->[0] and $_->[1] do).

Note that I removed the parts of the code irrelevant to the question. Using both XML::Twig and XML::LibXML in one program sounds very strange. 

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

[download]

Replies are listed 'Best First'.
Re^2: Need help with node names for creating header line
by vlturner (Sexton) on Dec 30, 2015 at 20:33 UTC

    So I used this and it runs, But still not what I was working to get. What I want is a CSV file with a header 

    
COL_HDR1,COL_HDR2,COL_HDR3
   DATA1,   DATA2,   DATA3

    [download]
[reply]
[d/l]
      Keep a flag that tells you whether the header was already printed, if so, extract text, otherwise extract names: 
      my $header_printed;
for my $record (@sorted) {
    my @info_tags = $record->children;
    my @data;

    for my $info_tag (@info_tags) {
        my $extract = $header_printed ? 'text' : 'name';
        push @data, $info_tag->$extract;
    }
    $header_printed = 1;
    say join ',', @data;
}

      [download]
      ($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

      [download]
[reply]
[d/l]
[select]

        Getting following error: 

        perl CMDB_Sample.pl
Can't use string ("change_request") as an ARRAY ref while "strict refs
+" in use at CMDB_Sample.pl line 56.

        [download]
[reply]
[d/l]

        Got it, had typo. This code is part of an integration to Service Now CMDB Is there a way that I can add this to the Tutorials for dealing with this DATABASE as the code matures?

[reply]

        Stupid me.... say join ',', map qq("$_"), @data;

[reply]

In Section Seekers of Perl Wisdom