You can use the range operator (aka flip-flop):

    while ( <$fh> ) {
        print if /X/ .. /^\s*$/ and not /^\s*$/;
    }
[download]

Edit: updated to fix a precedence problem with if ( $line =~ /X/i .. /^\s*$/ ), thanks Eily!

I'll ++ your post as soon as I get votes. It still contains a mistake though. Since =~ is of higher precedence than .., your code is actually parsed as ($line =~ /X/i) .. /^\s*$/ which means the second regex will be applied on $_. Adding parentheses like this: $str =~ (/A/../B/) won't work either because this will apply the regular expressions first, on $_ (and this also happens to be the range operator, not flip flop).

Here, using the default variable $_ is the best option for readability:

while (<DATA>)
{
  if (/A/../B/)
  {
     print;
  }
}
__DATA__
1
2
A
3
4
B
5
6
[download]

The wording of the OP seems to imply that the blank line that ends the range should not actually be printed, as 1nickt attempts. Adding another && condition after the flip-flop achieves that.

$ perl -Mstrict -Mwarnings -E '
open my $inFH, q{<}, \ <<EOD or die $!;
Seb
Xavier
Peter

Roland
Jim
Xerox
Paddle

Yoyo
EOD

while ( <$inFH> )
{
    print if ( m{X} .. m{^\s*$} ) && ! m{^\s*$};
}'
Xavier
Peter
Xerox
Paddle
$
[download]

I hope this is of interest.

Cheers,

JohnGG

Thank you both very much!

This is what ended up working perfectly-

use strict;
use warnings;

my $file = $ARGV[0]; 

open( my $fh, '<', $file ) or die "Can't open $file: $!";

while ( <$fh> ) {

        if ( /Error:/i .. /^\s*$/ ) {
            print;
        }
    }
    close $fh;
[download]

Error: was my keyword and I wanted all of the error message below it until a blank line was found.

Thanks again!

Thanks for the correction. I was hewing as closely as possible to the OP's code and didn't test before posting; I guess I've always used it with $_. Updated and noted in my reply.



The way forward always starts with a minimal test.

For further discussion of the  .. scalar range operator and this particular (idiomatic) application of it, please see:

• perlfaq6 "How can I pull out lines between two patterns that are themselves on different lines?";
• The Scalar Range Operator and Flipin good, or a total flop? in Tutorials;
• Range Operators (as a scalar operator) in perlop.

I know you already have your answer but this is what I do in instances like those

my $flag;
while(<$fh>){
    chomp;
    if (/this/) { $flag = 1; next;}
    elsif (/^\s*$/) {$flag = 0;}
    print "$_\n" if $flag;
}
close($fh);
[download]

In this case it would print everything BETWEEN the line "this" (but not include that line) and would end once a blank line is found (and not include it)