G'day rkeshvardoost,

You have some questionable code here. Consider these two adjacent lines:

package R;
package R::startR;
[download]

Are you missing some code that should come after package R;? If not, why did you use package R; in the first place?

The use lib 'R'; line seems to be in the wrong place in your code. Without knowing your directory structure, I can't even say if it's correct (regardless of its position).

In this part of your code:

package R::startR;
...
@EXPORT_OK = qw(startR ...
[download]

that refers to R::startR::startR. Was that what you meant? If so, you haven't declared it!

At this point, I'm starting to have to make many guesses as to your actual intent. The following is how I might have written something that may be close to what you want.

Firstly, I created a directory (pm_1152700_libs) and populated it like this:

$ cat pm_1152700_libs/R.pm
package R;
use Exporter 'import';
our @EXPORT_OK = qw{startR};
sub startR { print 'This is &R::startR' }
1;
[download]

$ cat pm_1152700_libs/R/startR.pm
package R::startR;
use Exporter 'import';
our @EXPORT_OK = qw{startR};
sub startR { print 'This is &R::startR::startR' }
1;
[download]

I then wrote this test script (but do see the notes I've written afterwards):

#!/usr/bin/env perl -l

use strict;
use warnings;

use lib 'pm_1152700_libs';

use R qw{startR};
use R::startR qw{startR};

R::startR();
R::startR::startR();
[download]

which outputs

This is &R::startR
This is &R::startR::startR
[download]

You've used startR in both module and subroutine names. This is highly error-prone and I'd recommend you think of better names.

I've repeated the use of startR in both module and subroutine names; however, note the following:

• To disambiguate the calls to the two &startR routines, I've needed to use fully qualified names, i.e. R::startR() and R::startR::startR().
• If you are going to use fully qualified names, there's little point in adding those identical symbols to your import lists (or even to @EXPORT_OK).
• With better names, the last few lines of my test script could look more like this:

  use R qw{some_startR};
  use R::startR qw{other_startR};
  
  some_startR();
  other_startR();
  [download]

Finally, I strongly advise that you use the strict and warnings pragmata at the start of all your scripts.