I also fixed the code in order to be able to run it with the data you showed (no commas, no root node) and without creating any files. Adapt to your desires as needed.

#!/usr/bin/perl
use warnings;
use strict;

use XML::Writer;

my @array = split /\n/, << '__CSV__';
name    subname        start size
CAL_M    reserved        0    13
CAL_M    o_check_out    13    7
CAL_M    o_ttr_first    20    4
CAL_M    o_cal_check_1  24    4
PSQN_0    reserved       0    8
PSQN_0    check_final    8    10
PSQN_0    o_check       18    10
__CSV__

my $writer = 'XML::Writer'->new( DATA_MODE   => 1,
                                 DATA_INDENT => 2);

$writer->startTag('root');

my $prev_name = q();
for my $item(@array) {
    chomp $item;
    if (my ($name, $sname, $start, $size) = $item =~/(\w+)\s+(\w+)\s+(
+\d+)\s+(\d+)/) {

        if ($prev_name ne $name) {
            if ($prev_name) {
                $writer->endTag('structure');
            }
            $writer->startTag('structure', name => $name);
        }
        $writer->startTag('value', type  => $size,
                                   name  => $sname,
                                   start => $start,
                         );
        $writer->endTag('value');
        $prev_name = $name;
    }
}
$writer->endTag($_) for qw( structure root );
$writer->end;
[download]

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

thanks choroba. btw, what does this actually do? my $prev_name = q(); is it the same as my $prev_name = ''; ?

Yes, it is entirely equivalent. See perlop for the details.

Build a hash of arrays (HoA) perhaps.

#!perl
use strict;
use warnings;
use XML::Writer;
use Text::CSV;

my $csv = Text::CSV->new ( 
    { binary   => 1,
      sep_char => ',',
      eol      => $\,
    }  )  
    or die "Cannot use CSV: ".Text::CSV->error_diag ();
 
#input file
my $input_file = 'in.csv';
open my $fh_in,'<',$input_file
   or die "cannot open $input_file : $!";
        
my %hash=();
while ( my $line = $csv->getline( $fh_in ) ){
  my $name = $line->[0];
  push @{$hash{$name}},$line;
}
close $fh_in;

#output file
my $output_file = "myfile.xml";
open my $fh_out,'>',$output_file
   or die "cannot open $output_file : $!";

my $writer = new XML::Writer( OUTPUT      => $fh_out, 
                              DATA_MODE   => 1, 
                              DATA_INDENT => 2 );

for my $name (sort keys %hash){
  $writer->startTag("structure", "name"=>$name); 
  for my $ar ( @{$hash{$name}} ){
    $writer->startTag("value", "name" => $ar->[1], 
                               "start"=> $ar->[2], 
                               "type" => $ar->[3]); 
    $writer->endTag("value");
  }  
  $writer->endTag("structure");
  $writer->end();
}
close $fh_out;
[download]

thanks poj. I try to do it in hashes before, but not really familiar and got some error. That's why I switched back to array.