Ppeoc has asked for the wisdom of the Perl Monks concerning the following question:

Hi Monks! I am trying to write a sub function that returns values to the main function using TK GUI. I got the listbox working but cant seem to get the text box to return values to the main function. Here is my code, 
sub myListBox{
my @choice1;
my $path;
my @listbox_items = @_;

my $mw = MainWindow->new;
$mw->protocol('WM_DELETE_WINDOW',sub{return;});
my $lsb = $mw -> Frame();
$mw->title("Select terms");
my $lb = $mw->Scrolled("Listbox", 
       -scrollbars => "osoe",
       -height => 200,
       -width => 400,
       -selectmode => "multiple",
       -exportselection =>1)->pack( );
       
       $lb->insert('end', @listbox_items);
       $lb->pack(-side => "left");
       $lb->Button(-text => "Exit",
             -command => sub{exit; })->pack(-side => "bottom",
                                     -fill => 'x');
       $mw->Button(-text=>"Select", 
             -command => sub {
            foreach ($lb->curselection()) {
                        push @choice1, $listbox_items[$_];
                        }
                     $mw->destroy()},
     )->pack(-side => "bottom",
            -fill => 'x');

                            
my $label = $mw->Label(-text=>"Enter Directory Path:")->pack( );      
+                      
my $entry = $mw->Entry()->pack( );
my $localpath = $entry->get();
MainLoop;

return @choice1,$localpath;
}

[download]
No value is returned for $localpath. The code runs fine for just the listbox. But when I start adding radio buttons and text boxes, the code gets messed up. My idea is to have a listbox in the left, radiobuttons on top right and text box on bottom right. Any help will be highly appreciated.

Replies are listed 'Best First'.
Re: Listbox, radio buttons and text box in sub function?
by choroba (Cardinal) on Feb 10, 2016 at 13:36 UTC
    The problem is that the line 
    my $localpath = $entry->get();

    [download]

    runs before the MainLoop(), so nothing is assigned to $localpath. That's why Entries have textvariables: 

    my $entry = $mw->Entry( -textvariable => \ my $localpath )->pack;

    [download]

    Update: It seems the last item in the list is not displayed, or rather, the Exit button is displayed over it. Don't put the button into the list, it might be better to use the unused $lsb frame for both the list and the button. 

    ($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

    [download]
[reply]
[d/l]
[select]
      Hey, Thanks for the suggestion. Looks like I am still having issues with this as well. The text entered is being lumped into the array @choice1 i.e. it is the last element of the array and $localpath still has no value. Any suggestions??
[reply]
        The problem probably comes from a part of the code you didn't show: 
        my (@choice1, $localpath) = myListBox(qw( item1 item2 item3 ));

        [download]

        This indeed doesn't work, as assignment to an array gobbles up all the values from the right hand side. Swap the arguments, or return an array reference. 

        return ($localpath, @choice1)
# ...
my ($localpath, @choice1) = myListBox(qw( item1 item2 item3 ));

# OR

return (\@choice1, $localpath)
# ...
my ($choice_ref, $localpath) = myListBox(qw( item1 item2 item3 ));

        [download]
        ($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,

        [download]
[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom