If you have a recent version of List::MoreUtils

use List::MoreUtils qw( singleton  );
my $str = join '',singleton 
         split '',"abcdefghiaabccdjklm";
print $str;
[download]

use strict;
use warnings;

my $str = "abcdefghiaabccdjklm";
my @chars = split //, $str;
my %uniq;
$uniq{$_}++ for @chars;
$str = '';
for (@chars) {
    $str .= $_ unless $uniq{$_} > 1;
}
print $str;

__END__

efghijklm
[download]

Still executes in a loop, but gets all instances of each letter each time (thus avoids the even/odd issue you have).

use 5.010;
my $str = "abcdefghiaabccdjklm";
my $substr;
$substr = "" while $str =~ s/(.)(?:(.*?)\1(?{ $substr .= $^N }))+/$sub
+str/;
say $str;
[download]

I have no better solution than to do a loop but your regex always removes pairs of characters, so if you have an odd number of a character one will remain. Is that what you want?

# warning win32 doublequote

perl -e "print grep {$res{$_}==1} map {++$res{$_};$_} split '',$ARGV[0
+]" abcdefghiaabccdjklm
efghijklm
[download]

L*

A solution with s/// seems inefficient. And the loop is probably unavoidable: you'd need either variable lookbehind, or multiple matches on same text. Anyway:

my $str = "abcdefghiaabccdjklm";
print "Input : $str\n";
1 while $str =~ s/(.)(.*?(?=\g1))((?=.+?\g1)|.)/$2/;
print "Output: $str\n";
[download]

G'day punitpawar,

"Is there a way by making use of s/// ..."

You're starting with a solution and then trying to make it fit a problem. This is back-to-front: start with a problem and then find an appropriate solution.

The output of your second example (cdghijkmnoestsr) contains an 'e' which shouldn't be there: the original string (abcdeffghijkllmnoppqestqaserb) contains three 'e's.

As others have already noted, s/// does not seem appropriate. Here's how I might have tackled this problem:

#!/usr/bin/env perl -l

use strict;
use warnings;

my @test_strings = qw{
    abcdefghiaabccdjklm
    abcdeffghijkllmnoppqestqaserb
}; 

remove_duplicate_chars($_) for @test_strings;

sub remove_duplicate_chars {
    my $str = shift;

    my %seen;
    my @chars = grep { ! $seen{$_}++ } split //, $str;
    my $uniq = join '', grep { $seen{$_} == 1 } @chars;

    print "IN:  $str";
    print "OUT: $uniq";

    return;
}
[download]

Output:

IN:  abcdefghiaabccdjklm
OUT: efghijklm
IN:  abcdeffghijkllmnoppqestqaserb
OUT: cdghijkmnotr
[download]

#!/usr/bin/perl -l

# http://perlmonks.org/?node_id=1155716

use strict;
use warnings;

my $input = "abcdefghiaabccdjklm";
my $want = "efghijklm";

print $input;

$input =~ s/.(??{ -1 == index("$`$'", $&) && '(*FAIL)' })//g;

print $input;
print $want;
$input eq $want and print "Match!";
[download]

hehehe