Hello perlato,

First, you need to open the output file before the while loop. Second, you need to change:

print $_;
[download]

to:

print $ofh $_;
[download]

Note: Do not put a comma between the output filehandle and the (first) item to be printed. See print.

Hope that helps,

G'day perlato,

Welcome to the Monastery.

It looks like you were doing fine up to the flip-flop conditional (if (/TRANSACTION STARTED/ .. /TRANSACTION END/) {...}) and then got a bit lost.

You can do all the remaining processing within that if block. Here you'll want to do one of three things:

1. If /TRANSACTION STARTED/ is TRUE, open a new file for writing. (Don't output the line.)
2. If /TRANSACTION END/ is TRUE, close the filehandle. (Don't output the line.)
3. Output all lines that don't match either condition in 1 or 2.

The coding required is very straightforward:

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

my $filename_prefix = 'pm_1155986_out_';
my $filename_suffix = '.txt';
my $filename_number = 0; 
my $out_fh;
my ($start_re, $end_re) = (qr{TRANSACTION STARTED}, qr{TRANSACTION END
+});

open my $in_fh, '<', 'pm_1155986_in.txt';

while (<$in_fh>) {
    if (/$start_re/ .. /$end_re/) {
        if (/$start_re/) {
            open $out_fh, '>',
                $filename_prefix . $filename_number++ . $filename_suff
+ix;
            next;
        }

        if (/$end_re/) {
            close $out_fh;
            next;
        }

        print $out_fh $_;
    }
}
[download]

[Note I've used the autodie pragma. This avoids having to hand-craft ... or die "..." messages for all the I/O operations: a tedious and error-prone activity (which Perl will do for you if you ask it nicely).]

Here's all the input and output data (within the spoiler):

Just FYI, FWIW, the .. operator has a couple of features that can replace the duplicated regex matching.

First, the value of .. isn't just FALSE or TRUE, it's also a line number relative to the start of the range. Before the start, the value is 0 (aka FALSE). When the start of the range is matched, the value is 1. this number increments until the end of the range. So, you can:

my $rln = /$start_re/ .. /$end_re/;
if $rln == 1
{
    # open output file
    next;
}
if $rln > 1
{
   print $out_fh $_;
}
[download]

Second, when the range ends, the number has 'E0' appended. So, you can:

if rindex($rln, 'E0')
{
    close $out_fh;
    next;
}
[download]

rindex is a simple string search that works backwards, so has much less overhead than another regex match. And appending 'E0' to a string of digits is still a valid number - numerically equal to the number without the 'E0'.

your definition of $outputfile is wrong: it is a directory, impossible to write there, then you are never writing to $ofh anyway. In addition where are you creating a different outfile for each transaction?

Try to describe the correct procedure in english an then try to translate to Perl.

Doing everything during the while loop can be tricky for your Perl level (maybe), so try to semplify the process: put your distinct part of interest into a datastructure you feel comfortable with (array? an hash? arrayOFarras?).

Then cycle the datastructure and for each element decide a filename, open it, write to it what you need, close it and pass to next element.

It not so hard, I think, but post the code in case of problems.

L*