in reply to Re^2: Read in a template file, populate using user input and and generate a new file
in thread Read in a template file, populate using user input and and generate a new file

If you can add placeholders [% name %] to your template.config file like this 

[module1]

;;path to speedseq package binary directory
$;SPEEDSEQ_BIN_DIR$; = /usr/local/packages/
;;Sequence file 1
$;Seq1File$; = "[% seq1 %]"
;;Sequence file 2
$;Seq2File$; = "[% seq2 %]"
;;Read Group
$;Read_Group$;='@RG\tID:NA12878\tSM:NA12878\tPL:ILLUMINA\tLB:NA12878\t
+PU:NA12878'
;;Reference
$;Reference$; = "[% ref %]"

[module2]

 ;;Output Chromosome
 $;Chromosome$; = "[% chr_list %]"
 ;;use --v for verbose summary
 $;OTHER_ARGS$; = --v

[download]

then you could use a templating module like Template::Toolkit or Template::Tiny

#!perl
use strict;
use Getopt::Long;
use Template;

my $msg = qq! perl $0 template.config 
  --seq1 USER_INPUT.txt     --Seq2 USER_INPT2.txt 
  --Ref  USER_INPUT_REF.txt --chr_list USER_INPUT_CHR.txt!;

my @options = qw(seq1=s seq2=s ref=s chr_list=s); # strings
my $vars={};
GetOptions ($vars,@options)
 or die ("Error in command line arguments\n");
 
# check for all options
my $input  = $ARGV[0];
die "$input not a valid template" 
     unless $input =~ /config/; # validate as req
for (@options){
  my @f = split '=';
  die "$msg" unless exists $vars->{$f[0]}; 
}

# create new template
my $output = 'new_'.$input;
my $tt = Template->new();
$tt->process($input,$vars,$output) 
  or die $tt->error(), "\n";

print "$output created\n";

[download]
poj

Replies are listed 'Best First'.
Re^4: Read in a template file, populate using user input and and generate a new file
by Bioinfocoder (Novice) on Feb 26, 2016 at 20:32 UTC
    Thanks a lot! This works perfect. But is there any way to populate without changing the input template file? Thanks again!
[reply]

      With some pattern matching perhaps

      #!perl
use strict;

# replace with Getopt::Long code as before
my $vars = {
  seq1 =>'USER_INPUT.txt',
  seq2 => 'USER_INPT2.txt',
  ref => 'USER_INPUT_REF.txt',
  chr_list => 'USER_INPUT_CHR.txt',
};
 
my $input = 'template.config';
open IN,'<',$input or die "Could not open $input : $!";
my $output = 'new_'.$input;
open OUT,'>',$output or die "Could not open $output : $!";

while (<IN>){
  chomp;
  # match selected lines
  # and append "value"
  if (/^ *\$;(Seq\d|Ref|Chromo).*\$; =/){
    my $key = ($1 eq 'Chromo') ? 'chr_list' : lc $1;
    $_ .= '"'.$vars->{$key}.'"';
  }
  print OUT $_."\n";  
}
close IN;
close OUT;

      [download]
      poj
[reply]
[d/l]

In Section Seekers of Perl Wisdom