Hi insta.gator,

Your code has lots of unneccessary cruft that makes it hard to read, a lot having to do with quotation ... I suggest a closer read through some introductory material such as perlsyn (Perl Syntax).

I cleaned up your code down to your problem line. It's below for your review. Untested and incomplete but should give you some ideas. Some things I did include:

• removing the chomp line (should do that when you build the array)
• using strict and declaring your variables in scope
• letting $file_size_met be a numeric value so 0 is false and anything above that is true
• prefix increment operator
• opening your filehandle with a lexically-scoped variable
• and maybe some other stuff, take a look.

In doing so I can see at least one issue which is that you are opening your OUTFILE1 each time through your while loop. I still can't see exactly what your problem is, but it looks like you want to stop writing to the file if it's reached a certain size, but not split a line. You think you're going to split a line, so you want to back up and start the next file from the start of the broken line. Right? Anyway, it's a lot like an XY Problem, and there are lots of ready-made solutions (check CPAN) that will allow you skip writing all that code yourself.

foreach my $filename (@prfiles) {
    my ( $total_recs, $counter_recs, $previous_rec_ssn, $file_count, $
+file_size_met );

    open ( my $INFILE1, '<', $filename ) or die "Cannot open $filename
+: $!";
    print "Now processing: $filename\n";
     
    while ( <$INFILE1> ) {
       if ( not $file_size_met ) {
           ++$file_count;
           my $mod_filename = $filename . $file_count;
           print "Writing output to: $mod_filename\n\n";
           
           open ( my $OUTFILE1, '>>' $mod_filename ) or die( 201 );
           
           while ( $counter_recs < 50000 ) {
               print $OUTFILE1 $_;
               ++$total_recs;
               ++$counter_recs;
           }
           
           print "$total_recs records have been processed\n";
           $counter_recs=0;
        }

        my $actual_size = (stat($mod_filename))[7];
        ++$file_size_met if $actual_size >= $outsize;
        print "Current file size is $actual_size bytes.\n";
[download]

Hope this helps!

It may be easier to think about if you turn the logic around: first, write some code that identifies when the record type changes. Then, when that happens, and your output file has reached the maximum size, you close your current output file and open the new one.

Also, don't use stat to check the current file size, since you don't need to go to the file system to find that out, use tell instead.

use warnings;
use strict;

# this just generates an example input file, not part of the solution
open my $tfh, '>', 'input.txt' or die $!;
print $tfh "$_\n" x (rand(3)+1) for 'A'..'Z';
close $tfh;

# now split the input file
my $MAXSIZE = 20;
open my $ifh, '<', 'input.txt' or die $!;
my $outcount=0;
open my $ofh, '>', 'out000.txt' or die $!;
my $prev;
while (<$ifh>) {
    chomp;
    if (defined $prev && $prev ne $_) {
        print STDERR "Record type switched from $prev to $_, output si
+ze is ".tell($ofh)."\n";
        if (tell($ofh)>$MAXSIZE) {
            close $ofh;
            my $ofn = sprintf 'out%03d.txt', ++$outcount;
            print STDERR "Opening new output file $ofn\n";
            open $ofh, '>', $ofn or die $!;
        }
    }
    print $ofh $_, "\n";
    $prev = $_;
}
close $ofh;
close $ifh;
[download]

Thanks to both 1nick2 and anonymous for the help. Yes, I am sure that my code is ugly and redundant and I am sure that there are better ways to do what I am trying to do. I am still learning. Self taught using a book. And since I don't do this for a living, I don't get a lot of practice. Thanks again. You answers were spot-on. -Gator